[arch-commits] Commit in opendht/repos (3 files)

[Bruno Pagani]

    Date: Monday, October 18, 2021 @ 17:10:58
  Author: archange
Revision: 1030848

archrelease: copy trunk to community-testing-x86_64

Added:
  opendht/repos/community-testing-x86_64/
  opendht/repos/community-testing-x86_64/PKGBUILD
    (from rev 1030847, opendht/trunk/PKGBUILD)
  opendht/repos/community-testing-x86_64/opendht-gcc11.patch
    (from rev 1030847, opendht/trunk/opendht-gcc11.patch)

---------------------+
 PKGBUILD            |   53 ++++++++++++++++++++++++++++++++++++++++++++++++++
 opendht-gcc11.patch |   12 +++++++++++
 2 files changed, 65 insertions(+)

Copied: opendht/repos/community-testing-x86_64/PKGBUILD (from rev 1030847, opendht/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-10-18 17:10:58 UTC (rev 1030848)
@@ -0,0 +1,53 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Baptiste Jonglez <baptiste--aur at jonglez dot org>
+
+pkgname=opendht
+epoch=1
+pkgver=2.3.1
+pkgrel=1
+pkgdesc="C++14 Distributed Hash Table (DHT) implementation"
+arch=(x86_64)
+url="https://github.com/savoirfairelinux/opendht"
+license=(GPL3)
+depends=(glibc gnutls nettle readline argon2 jsoncpp libjsoncpp.so fmt http-parser openssl)
+makedepends=(cmake msgpack-c msgpack-cxx asio restinio cython python-setuptools)
+checkdepends=(cppunit)
+optdepends=('python: to use the Python bindings')
+source=(${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz
+        opendht-gcc11.patch)
+sha256sums=('9a75db4f119761d6524964b27d3a49aa809a6cb08bde963edc2f338458433c78'
+            '4cd9ee51b3da01f00b0eb4367c48fb3a00df0840d5cf7beafaabcd149c8bd0fc')
+
+prepare() {
+  # https://github.com/savoirfairelinux/opendht/pull/567
+  patch -d ${pkgname}-${pkgver} -p1 < opendht-gcc11.patch
+}
+
+build() {
+  cmake -B build -S ${pkgname}-${pkgver} \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DOPENDHT_DOCUMENTATION=OFF \
+    -DOPENDHT_TESTS=ON \
+    -DOPENDHT_STATIC=OFF \
+    -DOPENDHT_SYSTEMD=ON \
+    -DOPENDHT_SYSTEMD_UNIT_FILE_LOCATION=/usr/lib/systemd/system/ \
+    -DOPENDHT_LTO=ON \
+    -DOPENDHT_INDEX=ON \
+    -DOPENDHT_PYTHON=ON \
+    -DOPENDHT_HTTP=ON \
+    -DOPENDHT_PROXY_SERVER=ON \
+    -DOPENDHT_PROXY_CLIENT=ON \
+    -DOPENDHT_PUSH_NOTIFICATIONS=ON
+  make -C build
+}
+
+check() {
+  # https://github.com/savoirfairelinux/opendht/issues/568
+  make -C build test || echo "Tests failed"
+}
+
+package() {
+  make -C build DESTDIR="${pkgdir}" install
+}

Copied: opendht/repos/community-testing-x86_64/opendht-gcc11.patch (from rev 1030847, opendht/trunk/opendht-gcc11.patch)
===================================================================
--- community-testing-x86_64/opendht-gcc11.patch	                        (rev 0)
+++ community-testing-x86_64/opendht-gcc11.patch	2021-10-18 17:10:58 UTC (rev 1030848)
@@ -0,0 +1,12 @@
+diff --git a/tests/threadpooltester.cpp b/tests/threadpooltester.cpp
+index be948f9..4a5199f 100644
+--- a/tests/threadpooltester.cpp
++++ b/tests/threadpooltester.cpp
+@@ -21,6 +21,7 @@
+ 
+ #include "opendht/thread_pool.h"
+ #include <atomic>
++#include <thread>
+ 
+ namespace test {
+ CPPUNIT_TEST_SUITE_REGISTRATION(ThreadPoolTester);