[arch-commits] Commit in libsecp256k1/repos (2 files)

[Bruno Pagani]

    Date: Monday, October 18, 2021 @ 18:23:22
  Author: archange
Revision: 1030879

archrelease: copy trunk to community-staging-x86_64

Added:
  libsecp256k1/repos/community-staging-x86_64/
  libsecp256k1/repos/community-staging-x86_64/PKGBUILD
    (from rev 1030878, libsecp256k1/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: libsecp256k1/repos/community-staging-x86_64/PKGBUILD (from rev 1030878, libsecp256k1/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-10-18 18:23:22 UTC (rev 1030879)
@@ -0,0 +1,52 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Maintainer: Baptiste Jonglez <archlinux at bitsofnetworks dot org>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+pkgname=libsecp256k1
+_gitcommit=9526874d1406a13193743c605ba64358d55a8785
+pkgver=20211017+1410+g9526874
+pkgrel=1
+pkgdesc="Optimized C library for EC operations on curve secp256k1"
+arch=(x86_64)
+url="https://github.com/bitcoin-core/secp256k1"
+license=(MIT)
+depends=(gmp)
+source=(${url}/archive/${_gitcommit}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('e7138d9262e52885d1c5de8f91138832c3a1875de509ce169934be20416b08d7')
+
+prepare() {
+  cd secp256k1-${_gitcommit}
+  autoreconf -vfi
+}
+
+build() {
+  cd secp256k1-${_gitcommit}
+  ./configure \
+    --prefix=/usr \
+    --sbindir=/usr/bin \
+    --libexecdir=/usr/bin \
+    --sysconfdir=/etc \
+    --sharedstatedir=/usr/share/libsecp256k1 \
+    --localstatedir=/var/lib/libsecp256k1 \
+    --disable-static \
+    --disable-benchmark \
+    --disable-coverage \
+    --enable-module-ecdh \
+    --enable-module-recovery \
+    --enable-tests \
+    --enable-exhaustive-tests \
+    --disable-openssl-tests \
+    --with-gnu-ld
+  make
+}
+
+check() {
+  cd secp256k1-${_gitcommit}
+  make check
+}
+
+package() {
+  cd secp256k1-${_gitcommit}
+  make DESTDIR="${pkgdir}" install
+  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}