[arch-commits] Commit in zellij/repos (community-x86_64 community-x86_64/PKGBUILD)
Orhun Parmaksiz
orhun at gemini.archlinux.org
Wed Oct 20 19:18:07 UTC 2021
Date: Wednesday, October 20, 2021 @ 19:18:07
Author: orhun
Revision: 1031448
archrelease: copy trunk to community-x86_64
Added:
zellij/repos/community-x86_64/
zellij/repos/community-x86_64/PKGBUILD
(from rev 1031447, zellij/trunk/PKGBUILD)
----------+
PKGBUILD | 39 +++++++++++++++++++++++++++++++++++++++
1 file changed, 39 insertions(+)
Copied: zellij/repos/community-x86_64/PKGBUILD (from rev 1031447, zellij/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD (rev 0)
+++ community-x86_64/PKGBUILD 2021-10-20 19:18:07 UTC (rev 1031448)
@@ -0,0 +1,39 @@
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+# Contributor: Julien Nicoulaud <julien.nicoulaud at gmail.com>
+
+pkgname=zellij
+pkgver=0.19.0
+pkgrel=1
+pkgdesc="A terminal multiplexer"
+arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
+url="https://zellij.dev"
+license=('MIT')
+depends=('gcc-libs')
+makedepends=('cargo')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/zellij-org/${pkgname}/archive/v${pkgver}.tar.gz")
+sha512sums=('03094e464fc3ab70ef47faf56dd72cfa91026d152d5517144eee067da978f622b278f1f54a45ce935a2062a0035240218766a72ddc0caa43c8babc651eaac198')
+
+prepare() {
+ cd "$pkgname-$pkgver"
+ cargo fetch --locked
+}
+
+build() {
+ cd "$pkgname-$pkgver"
+ RUSTUP_TOOLCHAIN=stable cargo build --release --frozen --all-features
+ ./target/release/zellij setup --generate-completion bash > target/zellij.bash
+ ./target/release/zellij setup --generate-completion fish > target/zellij.fish
+ ./target/release/zellij setup --generate-completion zsh > target/zellij.zsh
+}
+
+package() {
+ cd "$pkgname-$pkgver"
+ install -Dm755 target/release/zellij -t "${pkgdir}/usr/bin"
+ install -Dm644 GOVERNANCE.md README.md -t "${pkgdir}/usr/share/doc/zellij"
+ install -Dm644 LICENSE.md -t "${pkgdir}/usr/share/licenses/zellij"
+ install -Dm644 target/zellij.bash "${pkgdir}/usr/share/bash-completion/completions/zellij"
+ install -Dm644 target/zellij.fish "${pkgdir}/usr/share/fish/vendor_completions.d/zellij.fish"
+ install -Dm644 target/zellij.zsh "${pkgdir}/usr/share/zsh/site-functions/_zellij"
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list