[arch-commits] Commit in yaml-cpp/repos (2 files)

[Sven-Hendrik Haase]

    Date: Sunday, October 24, 2021 @ 23:15:16
  Author: svenstaro
Revision: 1033259

archrelease: copy trunk to community-staging-x86_64

Added:
  yaml-cpp/repos/community-staging-x86_64/
  yaml-cpp/repos/community-staging-x86_64/PKGBUILD
    (from rev 1033258, yaml-cpp/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: yaml-cpp/repos/community-staging-x86_64/PKGBUILD (from rev 1033258, yaml-cpp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-10-24 23:15:16 UTC (rev 1033259)
@@ -0,0 +1,42 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: David Runge <dvzrv at archlinux.org>
+# Contributor: Markus Martin <markus at archwyrm.net>
+
+pkgname=yaml-cpp
+pkgver=0.7.0
+pkgrel=1
+pkgdesc="YAML parser and emitter in C++, written around the YAML 1.2 spec"
+url="https://github.com/jbeder/yaml-cpp"
+arch=('x86_64')
+license=('MIT')
+depends=('gcc-libs' 'glibc')
+provides=('libyaml-cpp.so')
+makedepends=('cmake' 'ninja')
+source=("https://github.com/jbeder/yaml-cpp/archive/yaml-cpp-${pkgver}.tar.gz")
+sha512sums=('2de0f0ec8f003cd3c498d571cda7a796bf220517bad2dc02cba70c522dddde398f33cf1ad20da251adaacb2a07b77844111f297e99d45a7c46ebc01706bbafb5')
+
+build() {
+  cd "${pkgname}-${pkgname}-${pkgver}"
+  cmake -GNinja \
+        -Bbuild \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DBUILD_SHARED_LIBS=ON \
+        -DYAML_BUILD_SHARED_LIBS=ON \
+        -DCMAKE_BUILD_TYPE=Release
+  ninja -C build
+}
+
+check() {
+  cd "${pkgname}-${pkgname}-${pkgver}"
+  ninja -C build test
+  build/test/yaml-cpp-tests
+}
+
+package() {
+  cd "${pkgname}-${pkgname}-${pkgver}"
+  DESTDIR="$pkgdir" ninja -C build install
+  install -vDm 644 {CONTRIBUTING,README}.md -t "$pkgdir/usr/share/doc/$pkgname"
+  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+  rm -rf "${pkgdir}"/usr/{lib,lib/pkgconfig,include}/*{gtest,gmock}*
+  rm -rf "${pkgdir}"/usr/lib/cmake/GTest
+}