[arch-commits] Commit in afl/repos (3 files)

Evangelos Foutras foutrelis at gemini.archlinux.org
Mon Oct 25 00:51:43 UTC 2021


    Date: Monday, October 25, 2021 @ 00:51:43
  Author: foutrelis
Revision: 1033283

archrelease: copy trunk to community-staging-x86_64

Added:
  afl/repos/community-staging-x86_64/
  afl/repos/community-staging-x86_64/PKGBUILD
    (from rev 1033282, afl/trunk/PKGBUILD)
  afl/repos/community-staging-x86_64/llvm13.patch
    (from rev 1033282, afl/trunk/llvm13.patch)

--------------+
 PKGBUILD     |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 llvm13.patch |   11 +++++++++++
 2 files changed, 60 insertions(+)

Copied: afl/repos/community-staging-x86_64/PKGBUILD (from rev 1033282, afl/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-10-25 00:51:43 UTC (rev 1033283)
@@ -0,0 +1,49 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Santiago Torres-Arias <santiago[at]archlinux[dot]org>
+# Contributor: spider-mario <spidermario at free.fr>
+
+pkgname=afl
+pkgver=2.57b
+pkgrel=8
+pkgdesc='Security-oriented fuzzer using compile-time instrumentation and genetic algorithms'
+url='http://lcamtuf.coredump.cx/afl/'
+arch=('x86_64')
+license=('Apache')
+depends=('glibc' 'bash')
+optdepends=('gcc: gcc instrumentation support'
+            'clang: clang instrumentation support'
+            'llvm: experimental clang-fast instrumentation support'
+            'gnuplot: graph plotting support')
+makedepends=('clang' 'llvm' 'gcc' 'wget' 'python' 'lib32-glibc')
+provides=('american-fuzzy-lop')
+replaces=('american-fuzzy-lop')
+options=('!emptydirs' '!strip')
+source=(https://github.com/google/AFL/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz
+        llvm13.patch)
+sha256sums=('6f05a6515c07abe49f6f292bd13c96004cc1e016bda0c3cc9c2769dd43f163ee'
+            'ec000fddabc566ac8d2b1af0444843e384d93f7faa4ff55677db1507164ef26f')
+sha512sums=('5d12b96229e966aeb11deb47cd8eb36cde2fa32656eb187db02c7240909d6acda36be59b2baf7e42cddd228d25ec94c8bffc3fa27f7f4b5e1e462b62929ce75d'
+            '53f1739fe96b24add8b717a5f820ef6b938863c2434e60594bf66fb317808142c369b904d962eac3209128fcf02578b7e0f9908d6e8c53b2a4ebd0fe00ae1cf8')
+b2sums=('69029d59451e468528386154e8938a1a7303765e039f98aa05e36f07314398f60ff2578f765142e1f1ff653e5ab93ea53a2efb98abe275046ebacdd3ca8363b6'
+        '60c58a7bd115189a05866899852d760723c6dd255bd684ed90d61c1be56b8bd3bf8702aa9540ad4235469b2dc32253ee645b6f7ac7bbb924eb9f711c3a07e375')
+
+prepare() {
+  cd AFL-${pkgver}
+  # Minimal build fix for LLVM 13 inspired by:
+  # https://github.com/AFLplusplus/AFLplusplus/commit/1ba5d1008e74
+  patch -Np1 -i ../llvm13.patch
+}
+
+build() {
+  cd AFL-${pkgver}
+  make PREFIX=/usr
+  make -C llvm_mode PREFIX=/usr
+}
+
+package() {
+  cd AFL-${pkgver}
+  make PREFIX=/usr DESTDIR="${pkgdir}" install
+  install -Dm 644 llvm_mode/README.llvm -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:

Copied: afl/repos/community-staging-x86_64/llvm13.patch (from rev 1033282, afl/trunk/llvm13.patch)
===================================================================
--- community-staging-x86_64/llvm13.patch	                        (rev 0)
+++ community-staging-x86_64/llvm13.patch	2021-10-25 00:51:43 UTC (rev 1033283)
@@ -0,0 +1,11 @@
+diff -upr AFL-2.57b.orig/llvm_mode/afl-clang-fast.c AFL-2.57b/llvm_mode/afl-clang-fast.c
+--- AFL-2.57b.orig/llvm_mode/afl-clang-fast.c	2020-07-04 19:24:18.000000000 +0300
++++ AFL-2.57b/llvm_mode/afl-clang-fast.c	2021-10-25 03:48:15.025835829 +0300
+@@ -140,6 +140,7 @@ static void edit_params(u32 argc, char**
+ #endif /* ^USE_TRACE_PC */
+ 
+   cc_params[cc_par_cnt++] = "-Qunused-arguments";
++  cc_params[cc_par_cnt++] = "-flegacy-pass-manager";
+ 
+   while (--argc) {
+     u8* cur = *(++argv);



More information about the arch-commits mailing list