[arch-commits] Commit in qt6-webengine/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Antonio Rojas arojas at gemini.archlinux.org
Tue Oct 26 15:08:41 UTC 2021


    Date: Tuesday, October 26, 2021 @ 15:08:40
  Author: arojas
Revision: 426597

archrelease: copy trunk to testing-x86_64

Added:
  qt6-webengine/repos/testing-x86_64/
  qt6-webengine/repos/testing-x86_64/PKGBUILD
    (from rev 426596, qt6-webengine/trunk/PKGBUILD)

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Copied: qt6-webengine/repos/testing-x86_64/PKGBUILD (from rev 426596, qt6-webengine/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-10-26 15:08:40 UTC (rev 426597)
@@ -0,0 +1,36 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=qt6-webengine
+_qtver=6.2.1
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='Provides support for web applications using the Chromium browser project'
+depends=(qt6-webchannel qt6-location libxcomposite libxrandr pciutils libxss libxkbfile 
+         libevent snappy nss libxslt minizip ffmpeg re2 libvpx libxtst ttf-font)
+makedepends=(cmake ninja python2 python gperf jsoncpp qt6-tools pipewire nodejs)
+optdepends=('pipewire: WebRTC desktop sharing under Wayland')
+groups=(qt6)
+_pkgfn="${pkgname/6-/}-everywhere-src-$_qtver"
+source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
+sha256sums=('1f933cffb8671c1e71b6b2a4924cb6b3f9878388ae6298ac8d31a76c1ecffbb7')
+
+build() {
+  cmake -B build -S $_pkgfn -G Ninja \
+    -DCMAKE_TOOLCHAIN_FILE=/usr/lib/cmake/Qt6/qt.toolchain.cmake \
+    -DQT_FEATURE_webengine_system_ffmpeg=ON \
+    -DQT_FEATURE_webengine_system_icu=ON \
+    -DQT_FEATURE_webengine_proprietary_codecs=ON \
+    -DQT_FEATURE_webengine_kerberos=ON \
+    -DQT_FEATURE_webengine_webrtc_pipewire=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  install -Dm644 "$srcdir"/${_pkgfn}/src/3rdparty/chromium/LICENSE "$pkgdir"/usr/share/licenses/${pkgname}/LICENSE.chromium
+}



More information about the arch-commits mailing list