[arch-commits] Commit in (libzim6 libzim6/repos libzim6/trunk libzim6/trunk/PKGBUILD)

[Justin Kromlinger]

    Date: Sunday, October 31, 2021 @ 09:27:34
  Author: hashworks
Revision: 1035047

Release temporary v6 version of libzim

Added:
  libzim6/
  libzim6/repos/
  libzim6/trunk/
  libzim6/trunk/PKGBUILD

----------+
 PKGBUILD |   30 ++++++++++++++++++++++++++++++
 1 file changed, 30 insertions(+)

Added: libzim6/trunk/PKGBUILD
===================================================================
--- libzim6/trunk/PKGBUILD	                        (rev 0)
+++ libzim6/trunk/PKGBUILD	2021-10-31 09:27:34 UTC (rev 1035047)
@@ -0,0 +1,30 @@
+# Maintainer: Justin Kromlinger <hashworks at archlinux.org>
+pkgname=libzim6
+pkgver=6.3.2
+pkgrel=1
+pkgdesc="Reference implementation of the ZIM specification by the openZIM project, v6"
+license=('GPL2')
+arch=('x86_64')
+depends=('xapian-core' 'zlib' 'xz' 'icu' 'zstd')
+makedepends=('meson' 'gtest' 'git')
+provides=('libzim')
+url='https://github.com/openzim/libzim'
+source=("libzim-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
+sha256sums=('648fb5af65dd28a6b221b9294217939bf5abf929d706e7323ebb4196849a923c')
+
+build() {
+	cd "libzim-${pkgver}"
+	arch-meson build
+	ninja -C build
+}
+
+check() {
+	cd "libzim-${pkgver}/build"
+	SKIP_BIG_MEMORY_TEST=1 ninja meson-test
+}
+
+package() {
+	install -Dm644 "libzim-${pkgver}/COPYING" "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+	cd "libzim-${pkgver}/build"
+	DESTDIR="${pkgdir}" ninja install
+}