[arch-commits] Commit in devhelp/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Sunday, October 31, 2021 @ 20:57:36
  Author: heftig
Revision: 426909

archrelease: copy trunk to extra-x86_64

Added:
  devhelp/repos/extra-x86_64/PKGBUILD
    (from rev 426906, devhelp/trunk/PKGBUILD)
Deleted:
  devhelp/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  104 ++++++++++++++++++++++++++++++++++---------------------------
 1 file changed, 58 insertions(+), 46 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-10-31 20:57:36 UTC (rev 426908)
+++ PKGBUILD	2021-10-31 20:57:36 UTC (rev 426909)
@@ -1,46 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Jan de Groot <jgc at archlinux.org>
-# Contributor: Link Dupont <link at subpop.net>
-
-pkgname=devhelp
-pkgver=40.1
-pkgrel=1
-pkgdesc="API documentation browser for GNOME"
-url="https://wiki.gnome.org/Apps/Devhelp"
-arch=(x86_64)
-license=(GPL)
-depends=(webkit2gtk amtk)
-makedepends=(gtk-doc git appstream-glib gobject-introspection meson yelp-tools)
-groups=(gnome-extra)
-_commit=ebea24b7e37ecfad64c380887f5e85674494d236  # tags/40.1^0
-source=("git+https://gitlab.gnome.org/GNOME/devhelp.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/\.alpha/alpha/;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-
-  # Find books generated with gi-docgen
-  git cherry-pick -n 1da8190c1ce010d86c3ce2253513469d3abc4b9b
-}
-
-build() {
-  arch-meson $pkgname build \
-    -D gtk_doc=true \
-    -D plugin_emacs=true \
-    -D plugin_gedit=true \
-    -D plugin_vim=true
-  meson compile -C build
-}
-
-check() {
-  meson test -C build --print-errorlogs
-}
-
-package() {
-  meson install -C build --destdir "$pkgdir"
-}

Copied: devhelp/repos/extra-x86_64/PKGBUILD (from rev 426906, devhelp/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-10-31 20:57:36 UTC (rev 426909)
@@ -0,0 +1,58 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Link Dupont <link at subpop.net>
+
+pkgbase=devhelp
+pkgname=(devhelp devhelp-docs)
+pkgver=41.2
+pkgrel=1
+pkgdesc="API documentation browser for GNOME"
+url="https://wiki.gnome.org/Apps/Devhelp"
+arch=(x86_64)
+license=(GPL)
+depends=(webkit2gtk)
+makedepends=(git appstream-glib gobject-introspection meson yelp-tools
+             gi-docgen)
+_commit=f05e288031ba171e8a0a589d65cba693487726d9  # tags/41.2^0
+source=("git+https://gitlab.gnome.org/GNOME/devhelp.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd devhelp
+  git describe --tags | sed 's/\.alpha/alpha/;s/-/+/g'
+}
+
+prepare() {
+  cd devhelp
+}
+
+build() {
+  arch-meson devhelp build \
+    -D gtk_doc=true \
+    -D plugin_emacs=true \
+    -D plugin_gedit=true \
+    -D plugin_vim=true
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package_devhelp() {
+  groups=(gnome-extra)
+
+  meson install -C build --destdir "$pkgdir"
+
+  # Split -docs
+  mkdir -p docs/usr/share
+  mv -t docs/usr/share "$pkgdir"/usr/share/doc
+}
+
+package_devhelp-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+  options=(!strip)
+
+  mv -t "$pkgdir" docs/*
+}