[arch-commits] Commit in kde-dev-scripts/repos (testing-any testing-any/PKGBUILD)

Antonio Rojas arojas at gemini.archlinux.org
Thu Sep 2 10:25:29 UTC 2021


    Date: Thursday, September 2, 2021 @ 10:25:29
  Author: arojas
Revision: 423070

archrelease: copy trunk to testing-any

Added:
  kde-dev-scripts/repos/testing-any/
  kde-dev-scripts/repos/testing-any/PKGBUILD
    (from rev 423069, kde-dev-scripts/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: kde-dev-scripts/repos/testing-any/PKGBUILD (from rev 423069, kde-dev-scripts/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2021-09-02 10:25:29 UTC (rev 423070)
@@ -0,0 +1,40 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=kde-dev-scripts
+pkgver=21.08.1
+pkgrel=1
+pkgdesc='Scripts and setting files useful during development of KDE software'
+url='https://www.kde.org/'
+arch=(any)
+license=(GPL LGPL FDL)
+groups=(kde-applications kdesdk)
+depends=(perl)
+makedepends=(extra-cmake-modules kdoctools)
+source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
+sha256sums=('cc7c5e7eccf33c5a2751f1c6c588b14a81ae584229e525337bb8efdb8fc460df'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck at kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker at kde.org>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  # Fix python 2 path
+  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
+    "$pkgdir"/usr/bin/{zonetab2pot.py,kde-systemsettings-tree.py,reviewboard-am}
+  sed -i 's|#! /usr/bin/env python|#!/usr/bin/env python2|' \
+    "$pkgdir"/usr/bin/{kdelnk2desktop.py,kde_generate_export_header}
+
+# Install additional files
+  cd "$srcdir"/$pkgname-$pkgver
+  mkdir -p "$pkgdir"/usr/share/kde-dev-scripts
+  cp -r kde-devel-* gdb "$pkgdir"/usr/share/kde-dev-scripts
+}



More information about the arch-commits mailing list