[arch-commits] Commit in (4 files)
Caleb Maclennan
alerque at gemini.archlinux.org
Sat Sep 4 09:25:06 UTC 2021
Date: Saturday, September 4, 2021 @ 09:25:06
Author: alerque
Revision: 1010900
Migrate lua-cassowary from AUR
Added:
lua-cassowary/
lua-cassowary/repos/
lua-cassowary/trunk/
lua-cassowary/trunk/PKGBUILD
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Added: lua-cassowary/trunk/PKGBUILD
===================================================================
--- lua-cassowary/trunk/PKGBUILD (rev 0)
+++ lua-cassowary/trunk/PKGBUILD 2021-09-04 09:25:06 UTC (rev 1010900)
@@ -0,0 +1,49 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+
+pkgbase=lua-cassowary
+_rockname=${pkgbase#lua-}
+_project=$_rockname.lua
+pkgname=("$pkgbase" "lua51-$_rockname" "lua52-$_rockname" "lua53-$_rockname")
+pkgver=2.3.1
+_rockrel=1 # upstream rockrel 2 is only needed for installing with Luarocks 2.x
+pkgrel=2
+pkgdesc='The cassowary constraint solver'
+arch=(any)
+url="https://github.com/sile-typesetter/$_project"
+license=(MIT)
+_lua_deps=(penlight)
+makedepends=(lua
+ lua51
+ lua52
+ lua53
+ luarocks)
+_archive="$_project-$pkgver"
+source=("$_archive.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('1cdf42d8736ac39becef7d0ff635317e1b0952968c9c8a5a2755a25aed17499a')
+
+_package() {
+ cd "$_archive"
+ luarocks --lua-version="$1" --tree="$pkgdir/usr/" \
+ make --deps-mode=none --no-manifest "rockspecs/$_rockname-$pkgver-$_rockrel.rockspec"
+ install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}
+
+package_lua-cassowary() {
+ depends=(lua "${_lua_deps[@]/#/lua-}")
+ _package 5.4
+}
+
+package_lua51-cassowary() {
+ depends=(lua51 "${_lua_deps[@]/#/lua51-}")
+ _package 5.1
+}
+
+package_lua52-cassowary() {
+ depends=(lua52 "${_lua_deps[@]/#/lua52-}")
+ _package 5.2
+}
+
+package_lua53-cassowary() {
+ depends=(lua53 "${_lua_deps[@]/#/lua53-}")
+ _package 5.3
+}
More information about the arch-commits
mailing list