[arch-commits] Commit in (3 files)

[Maxime Gauduin]

    Date: Saturday, September 4, 2021 @ 10:35:52
  Author: alucryd
Revision: 1010992

add python-charset-normalizer for python-httpx

Added:
  python-charset-normalizer/
  python-charset-normalizer/trunk/
  python-charset-normalizer/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: python-charset-normalizer/trunk/PKGBUILD
===================================================================
--- python-charset-normalizer/trunk/PKGBUILD	                        (rev 0)
+++ python-charset-normalizer/trunk/PKGBUILD	2021-09-04 10:35:52 UTC (rev 1010992)
@@ -0,0 +1,45 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: lilydjwg <lilydjwg at gmail.com>
+# Contributor: lilac <lilac at build.archlinuxcn.org>
+# Contributor: Dimitris Kiziridis <ragouel at outlook.com>
+
+_name=charset-normalizer
+pkgname=python-charset-normalizer
+pkgver=2.0.4
+pkgrel=1
+pkgdesc='Encoding and language detection alternative to chardet'
+arch=(any)
+url=https://github.com/ousret/charset_normalizer
+license=(MIT)
+depends=(python)
+makedepends=(
+  git
+  python-setuptools
+)
+checkdepends=(python-pytest)
+_tag=558d1e20c0d7cbdba9e207742cc9f2791649a425
+source=(git+https://github.com/Ousret/charset_normalizer.git#tag=${_tag})
+b2sums=(SKIP)
+
+pkgver() {
+  cd charset_normalizer
+  git describe --tags
+}
+
+build() {
+  cd charset_normalizer
+  python setup.py build
+}
+
+check() {
+  cd charset_normalizer
+  python setup.py test
+}
+
+package() {
+  cd charset_normalizer
+  python setup.py install --root=$pkgdir --optimize=1 --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/python-charset-normalizer/
+}
+
+# vim: ts=2 sw=2 et: