[arch-commits] Commit in sile/repos (community-x86_64 community-x86_64/PKGBUILD)

[Caleb Maclennan]

    Date: Saturday, September 4, 2021 @ 17:38:38
  Author: alerque
Revision: 1011393

archrelease: copy trunk to community-x86_64

Added:
  sile/repos/community-x86_64/
  sile/repos/community-x86_64/PKGBUILD
    (from rev 1011392, sile/trunk/PKGBUILD)

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Copied: sile/repos/community-x86_64/PKGBUILD (from rev 1011392, sile/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2021-09-04 17:38:38 UTC (rev 1011393)
@@ -0,0 +1,66 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Adrián Pérez de Castro <aperez at igalia.com>
+
+pkgname=sile
+pkgdesc='Modern typesetting system inspired by TeX'
+pkgver=0.11.1
+pkgrel=2
+arch=(x86_64)
+url=https://www.sile-typesetter.org
+license=(MIT)
+_luadeps=(bit32
+           cassowary
+           cosmo
+           cliargs
+           expat
+           filesystem
+           linenoise
+           lpeg
+           luaepnf
+           penlight
+           repl
+           sec
+           socket
+           stdlib
+           utf8
+           vstruct
+           zlib)
+depends=(fontconfig
+         freetype2
+         harfbuzz
+         gentium-plus-font
+         git
+         icu
+         libpng # this goes with libtexpdf if ever split out to a library package
+         lua
+         "${_luadeps[@]/#/lua-}"
+         zlib)
+depends+=(libfreetype.so
+          libharfbuzz.so
+          libicudata.so
+          libicui18n.so
+          libicuio.so
+          libicuuc.so)
+checkdepends=(poppler)
+provides=(libtexpdf.so)
+_archive="$pkgname-$pkgver"
+source=("https://github.com/sile-typesetter/sile/releases/download/v$pkgver/$_archive.tar.xz")
+sha256sums=('a3e627d543bf07ff43ff06cacdbceb8f37aa056a31af25e68f706ad33f497d19')
+
+build () {
+	cd "$_archive"
+	./configure \
+		--prefix /usr \
+		--with-system-luarocks
+	make all
+}
+
+check () {
+	cd "$_archive"
+	make check
+}
+
+package () {
+	cd "$_archive"
+	make install DESTDIR="$pkgdir"
+}