[arch-commits] Commit in haskell-hledger-lib/repos (2 files)

Felix Yan felixonmars at gemini.archlinux.org
Wed Sep 8 03:16:28 UTC 2021


    Date: Wednesday, September 8, 2021 @ 03:16:27
  Author: felixonmars
Revision: 1012348

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hledger-lib/repos/community-staging-x86_64/
  haskell-hledger-lib/repos/community-staging-x86_64/PKGBUILD
    (from rev 1012347, haskell-hledger-lib/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-hledger-lib/repos/community-staging-x86_64/PKGBUILD (from rev 1012347, haskell-hledger-lib/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-09-08 03:16:27 UTC (rev 1012348)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hledger-lib
+pkgname=haskell-hledger-lib
+pkgver=1.22.2
+pkgrel=7
+pkgdesc="A reusable library providing the core functionality of hledger"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-ansi-terminal'
+         'haskell-base-compat-batteries' 'haskell-blaze-markup' 'haskell-call-stack'
+         'haskell-cassava' 'haskell-cassava-megaparsec' 'haskell-cmdargs' 'haskell-data-default'
+         'haskell-decimal' 'haskell-extra' 'haskell-file-embed' 'haskell-glob'
+         'haskell-hashtables' 'haskell-megaparsec' 'haskell-old-time' 'haskell-parser-combinators'
+         'haskell-pretty-simple' 'haskell-regex-tdfa' 'haskell-safe' 'haskell-tabular'
+         'haskell-tasty' 'haskell-tasty-hunit' 'haskell-timeit' 'haskell-uglymemo'
+         'haskell-unordered-containers' 'haskell-utf8-string')
+makedepends=('ghc' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('5536f118c5dfbcae1e5da2ae8f9bc80f7425b4f8ad4ebfd70d1b52a9fd5486e810f5bfd8b89fe741b5fddc79216dcf9cb4923cbd1db0d986490bea0cc662dc67')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list