[arch-commits] Commit in magma/repos (3 files)

[Konstantin Gizdov]

    Date: Thursday, September 9, 2021 @ 16:54:32
  Author: kgizdov
Revision: 1013099

archrelease: copy trunk to community-testing-x86_64

Added:
  magma/repos/community-testing-x86_64/
  magma/repos/community-testing-x86_64/PKGBUILD
    (from rev 1013098, magma/trunk/PKGBUILD)
  magma/repos/community-testing-x86_64/add_cuda86_arch.patch
    (from rev 1013098, magma/trunk/add_cuda86_arch.patch)

-----------------------+
 PKGBUILD              |   55 ++++++++++++++++++++++++++++++++++++++++++++++++
 add_cuda86_arch.patch |   19 ++++++++++++++++
 2 files changed, 74 insertions(+)

Copied: magma/repos/community-testing-x86_64/PKGBUILD (from rev 1013098, magma/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-09-09 16:54:32 UTC (rev 1013099)
@@ -0,0 +1,55 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: bartus <arch-user-repoᘓbartus.33mail.com>
+# Contributor: pingplug <pingplug at foxmail.com>
+# Contributor: cornholio <vigo.the.unholy.carpathian at gmail.com>
+
+pkgname=magma
+pkgver=2.6.1
+pkgrel=3
+pkgdesc="Matrix Algebra on GPU and Multicore Architectures"
+arch=('x86_64')
+url="https://icl.cs.utk.edu/magma/"
+license=('custom')
+depends=('blas' 'lapack' 'cuda')
+makedepends=('gcc-fortran' 'cmake' 'ninja')
+optdepends=('python: for examples and tests'
+            'gcc-fortran: Fortran interface')
+source=("${pkgname}-${pkgver}.tar.gz::http://icl.cs.utk.edu/projectsfiles/${pkgname}/downloads/${pkgname}-${pkgver}.tar.gz"
+        'add_cuda86_arch.patch')
+sha256sums=('6cd83808c6e8bc7a44028e05112b3ab4e579bcc73202ed14733f66661127e213'
+            '896a6b66b4e3c10fab9bb3ae27b6783c2fad3ebd5e204d62da9fdec443bd6c15')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+
+  patch -Np1 -i "${srcdir}/add_cuda86_arch.patch"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+
+  CC=/usr/bin/gcc \
+  CXX=/usr/bin/g++ \
+  FC=/usr/bin/gfortran \
+  cmake \
+    -Bbuild \
+    -GNinja \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_SHARED_LIBS=ON \
+    -DGPU_TARGET="sm_52 sm_53 sm_60 sm_61 sm_62 sm_70 sm_72 sm_75 sm_80 sm_86"
+  ninja -C build
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  DESTDIR="${pkgdir}" ninja -Cbuild install
+
+  install -d "${pkgdir}"/usr/share/magma/example
+  cp -r "${srcdir}"/magma-${pkgver}/example/* "${pkgdir}"/usr/share/magma/example/
+  install -d "${pkgdir}"/usr/share/magma/testing
+  cp -r "${srcdir}"/magma-${pkgver}/testing/* "${pkgdir}"/usr/share/magma/testing/
+  install -Dm644 "${srcdir}"/magma-${pkgver}/COPYRIGHT "${pkgdir}"/usr/share/licenses/magma/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:

Copied: magma/repos/community-testing-x86_64/add_cuda86_arch.patch (from rev 1013098, magma/trunk/add_cuda86_arch.patch)
===================================================================
--- community-testing-x86_64/add_cuda86_arch.patch	                        (rev 0)
+++ community-testing-x86_64/add_cuda86_arch.patch	2021-09-09 16:54:32 UTC (rev 1013099)
@@ -0,0 +1,19 @@
+diff --color -aur magma-2.6.1-old/CMakeLists.txt magma-2.6.1-new/CMakeLists.txt
+--- magma-2.6.1-old/CMakeLists.txt      2021-07-13 01:35:20.000000000 +0300
++++ magma-2.6.1-new/CMakeLists.txt      2021-07-21 11:02:28.014236200 +0300
+@@ -294,6 +294,15 @@
+         message( STATUS "    compile for CUDA arch 8.0 (Ampere)" )
+     endif()
+ 
++    if (GPU_TARGET MATCHES sm_86)
++        if (NOT MIN_ARCH)
++            set( MIN_ARCH 860 )
++        endif()
++        set( NV_SM ${NV_SM} -gencode arch=compute_86,code=sm_86 )
++        set( NV_COMP        -gencode arch=compute_86,code=compute_86 )
++        message( STATUS "    compile for CUDA arch 8.6 (Ampere)" )
++    endif()
++
+     if (NOT MIN_ARCH)
+         message( FATAL_ERROR "GPU_TARGET must contain one or more of Fermi, Kepler, Maxwell, Pascal, Volta, Turing, Ampere, or valid sm_[0-9][0-9]" )
+     endif()