[arch-commits] Commit in git-delta/repos (2 files)

[Caleb Maclennan]

    Date: Friday, September 10, 2021 @ 09:09:26
  Author: alerque
Revision: 1013367

archrelease: copy trunk to community-staging-x86_64

Added:
  git-delta/repos/community-staging-x86_64/
  git-delta/repos/community-staging-x86_64/PKGBUILD
    (from rev 1013366, git-delta/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: git-delta/repos/community-staging-x86_64/PKGBUILD (from rev 1013366, git-delta/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-09-10 09:09:26 UTC (rev 1013367)
@@ -0,0 +1,59 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor:  Kr1ss $(echo \<kr1ss+x-yandex+com\>|sed s/\+/./g\;s/\-/@/)
+# Contributor : ccorn
+
+pkgname=git-delta
+_pkgname=delta
+pkgver=0.8.3
+pkgrel=3
+pkgdesc='Syntax-highlighting pager for git and diff output'
+arch=('x86_64')
+url="https://github.com/dandavison/delta"
+license=('MIT')
+depends=('libgit2')
+makedepends=('rust')
+checkdepends=('git')
+optdepends=(
+  'bash-completion: for shell auto-completion'
+  'zsh-completions: for shell auto-completion'
+)
+options=('!lto')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+b2sums=('a27fe07538acfd6346bc12f2e4ad03396737e268ce4653b25c908fbcc7bb47fe2ed76550dc431ab80bf9ab86746d4cd9b551ea68a47e603ae9fe99aa935df7bf')
+
+prepare() {
+  cd "$_pkgname-$pkgver"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$_pkgname-$pkgver"
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  cd "$_pkgname-$pkgver"
+  # some tests hang for 60+ seconds, find out why
+  # took my machine ~ 470 seconds
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/delta
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+
+  # shell auto-completions
+  install -vDm644 etc/completion/completion.bash \
+    "$pkgdir/usr/share/bash-completion/completions/$_pkgname"
+  install -vDm644 etc/completion/completion.zsh \
+    "$pkgdir/usr/share/zsh/site-functions/_$_pkgname"
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+}