[arch-commits] Commit in geany-plugins/repos (2 files)

Alexander Rødseth arodseth at gemini.archlinux.org
Fri Sep 10 14:11:31 UTC 2021


    Date: Friday, September 10, 2021 @ 14:11:30
  Author: arodseth
Revision: 1013476

archrelease: copy trunk to community-staging-x86_64

Added:
  geany-plugins/repos/community-staging-x86_64/
  geany-plugins/repos/community-staging-x86_64/PKGBUILD
    (from rev 1013475, geany-plugins/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: geany-plugins/repos/community-staging-x86_64/PKGBUILD (from rev 1013475, geany-plugins/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-09-10 14:11:30 UTC (rev 1013476)
@@ -0,0 +1,42 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Angel 'angvp' Velasquez <angvp at archlinux.org>
+# Contributor: Gerardo Exequiel Pozzi <vmlinuz386 at gmail.com>
+# Contributor: Patrick Melo <patrick at patrickmelo.eti.br>
+
+pkgname=geany-plugins
+pkgver=1.37
+pkgrel=4
+pkgdesc='Plugins for Geany'
+arch=(x86_64)
+url='https://plugins.geany.org/'
+license=(GPL)
+depends=(ctpl "geany>=$pkgver" gpgme gtkspell3 libgit2 lua51 python vte3 webkit2gtk)
+makedepends=(cppcheck intltool)
+source=("$url$pkgname/$pkgname-$pkgver.tar.bz2"{,.sig})
+b2sums=('4e6043b38d2756646275bdb8f5432c8285d9db09143b3a86edd3cac3ef5c0a1910731582c1fe4381f914480c82bd2c2e69b1184b220182cf35a828281596cce0'
+        'SKIP')
+validpgpkeys=('6BEC027CD44552A5B566F28DB7A4039D0630EA07') # Frank Lanitz <frank at geany.org>
+
+prepare() {
+  cd $pkgname-$pkgver
+  autoreconf -fi
+
+  # don't redefine bool
+  sed -i 's/typedef unsigned int bool/#include <stdbool.h>/g' \
+    pretty-printer/src/PrettyPrinter.h
+}
+
+build() {
+  cd $pkgname-$pkgver
+  export CFLAGS+=' -w'
+  export PYTHON=/usr/bin/python
+  ./configure --prefix=/usr --libexecdir=/usr/lib
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
+}
+
+# getver: plugins.geany.org/downloads.html



More information about the arch-commits mailing list