[arch-commits] Commit in python-ufolib2/repos (community-any community-any/PKGBUILD)

[Caleb Maclennan]

    Date: Tuesday, September 14, 2021 @ 21:48:31
  Author: alerque
Revision: 1014953

archrelease: copy trunk to community-any

Added:
  python-ufolib2/repos/community-any/
  python-ufolib2/repos/community-any/PKGBUILD
    (from rev 1014952, python-ufolib2/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: python-ufolib2/repos/community-any/PKGBUILD (from rev 1014952, python-ufolib2/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2021-09-14 21:48:31 UTC (rev 1014953)
@@ -0,0 +1,37 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Guillaume Horel <guillaume.horel at gmail.com>
+
+_pyname=ufoLib2
+pkgname=python-${_pyname,,}
+pkgver=0.11.2
+pkgrel=2
+pkgdesc='A library to deal with UFO font sources'
+arch=(any)
+url="https://github.com/fonttools/$_pyname"
+license=(Apache)
+_pydeps=(attrs
+         fonttools
+         fs) # for fonttools[ufo]
+depends=(python
+         "${_pydeps[@]/#/python-}")
+makedepends=(python-setuptools-scm)
+checkdepends=(python-pytest)
+_archive="$_pyname-$pkgver"
+source=("https://files.pythonhosted.org/packages/source/${_pyname::1}/$_pyname/$_archive.zip")
+sha256sums=('062a949296238574baf2ed35dd342eea58c4889b619dde266b55a242d4d1a3d5')
+
+build() {
+	cd "$_archive"
+	python setup.py build
+}
+
+check() {
+	cd "$_archive"
+	PYTHONPATH=src pytest tests
+}
+
+package() {
+	cd "$_archive"
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}
+