[arch-commits] Commit in haskell-lens-aeson/repos (2 files)

[Felix Yan]

    Date: Wednesday, September 15, 2021 @ 08:16:29
  Author: felixonmars
Revision: 1015299

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-lens-aeson/repos/community-staging-x86_64/
  haskell-lens-aeson/repos/community-staging-x86_64/PKGBUILD
    (from rev 1015298, haskell-lens-aeson/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-lens-aeson/repos/community-staging-x86_64/PKGBUILD (from rev 1015298, haskell-lens-aeson/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-09-15 08:16:29 UTC (rev 1015299)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=lens-aeson
+pkgname=haskell-lens-aeson
+pkgver=1.1.1
+pkgrel=54
+pkgdesc="Law-abiding lenses for aeson"
+url="https://github.com/lens/lens-aeson/"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-lens' 'haskell-scientific'
+         'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'uusi')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a72cd51a51dcb9b686909caac83f8f7ba69b0e33ba90bf8a55937f198f898a7e19dff24bec9a4b921b170f34c5511bd58df5ba1dea3751f37e374bb7193d388c')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -u attoparsec $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-test-doctests
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}