[arch-commits] Commit in xmobar/repos (2 files)

[Felix Yan]

    Date: Thursday, September 16, 2021 @ 23:22:31
  Author: felixonmars
Revision: 1016721

archrelease: copy trunk to community-staging-x86_64

Added:
  xmobar/repos/community-staging-x86_64/
  xmobar/repos/community-staging-x86_64/PKGBUILD
    (from rev 1016720, xmobar/trunk/PKGBUILD)

----------+
 PKGBUILD |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

Copied: xmobar/repos/community-staging-x86_64/PKGBUILD (from rev 1016720, xmobar/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-09-16 23:22:31 UTC (rev 1016721)
@@ -0,0 +1,69 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+# Contributer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=xmobar
+pkgver=0.39
+pkgrel=9
+pkgdesc='Minimalistic Text Based Status Bar'
+url='https://hackage.haskell.org/package/xmobar'
+license=('BSD')
+arch=('x86_64')
+depends=('libxft' 'libxinerama' 'libxrandr' 'libxpm' 'ghc-libs' 'haskell-x11'
+         'haskell-x11-xft' 'haskell-utf8-string' 'haskell-network-uri'
+         'haskell-hinotify' 'haskell-parsec-numbers'
+         'haskell-regex-compat' 'haskell-old-locale'
+         'haskell-http' 'haskell-dbus' 'haskell-libmpd' 'haskell-cereal' 'haskell-netlink'
+         'haskell-async' 'haskell-aeson'
+         'haskell-timezone-olson' 'haskell-timezone-series' 'alsa-lib'
+         'haskell-extensible-exceptions' 'haskell-http-conduit'
+         'haskell-http-types' 'haskell-http-client-tls' 'haskell-alsa-core' 'haskell-alsa-mixer')
+makedepends=('ghc' 'uusi' 'haskell-hspec' 'haskell-temporary')
+source=(https://github.com/jaor/xmobar/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('a47d7cf16fdea4bece1d622db1c2ac76acc9d9369043eec6ff41a22c1f59c9757932fbcebfe804a636c783e9a66317bb3aaf72edc4a373c48e7db3c9292d9658')
+
+prepare() {
+  cd xmobar-${pkgver}
+  uusi -u base xmobar.cabal
+}
+
+build() {
+  cd xmobar-${pkgver}
+
+  _flags=(with_xft with_utf8 with_inotify with_mpd with_alsa with_nl80211
+          with_datezone with_mpris with_dbus with_xpm with_threaded
+          with_rtsopts with_weather)
+
+  runhaskell setup configure -O \
+    --enable-shared \
+    --enable-executable-dynamic \
+    --disable-library-vanilla \
+    --prefix=/usr \
+    --dynlibdir=/usr/lib \
+    --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie' \
+    --flags="${_flags[*]}" \
+    --enable-tests
+  runhaskell setup build
+  runhaskell setup register --gen-script
+  runhaskell setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd xmobar-${pkgver}
+  runhaskell setup test
+}
+
+package() {
+  cd xmobar-${pkgver}
+  install -Dm 744 register.sh   "${pkgdir}/usr/share/haskell/register/xmobar.sh"
+  install -Dm 744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/xmobar.sh"
+  runhaskell setup copy --destdir="${pkgdir}"
+  install -Dm 644 license -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: