[arch-commits] Commit in qtile/repos/community-x86_64 (4 files)
David Runge
dvzrv at gemini.archlinux.org
Fri Sep 17 18:56:27 UTC 2021
Date: Friday, September 17, 2021 @ 18:56:27
Author: dvzrv
Revision: 1016879
archrelease: copy trunk to community-x86_64
Added:
qtile/repos/community-x86_64/PKGBUILD
(from rev 1016878, qtile/trunk/PKGBUILD)
qtile/repos/community-x86_64/qtile.install
(from rev 1016878, qtile/trunk/qtile.install)
Deleted:
qtile/repos/community-x86_64/PKGBUILD
qtile/repos/community-x86_64/qtile.install
---------------+
PKGBUILD | 223 +++++++++++++++++++++++---------------------------------
qtile.install | 20 ++---
2 files changed, 105 insertions(+), 138 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2021-09-17 18:56:18 UTC (rev 1016878)
+++ PKGBUILD 2021-09-17 18:56:27 UTC (rev 1016879)
@@ -1,128 +0,0 @@
-# Maintainer: David Runge <dvzrv at archlinux.org>
-
-pkgname=qtile
-pkgver=0.18.0
-pkgrel=2
-pkgdesc="A full-featured, pure-Python tiling window manager"
-arch=('x86_64')
-url="http://www.qtile.org"
-license=('MIT')
-depends=(
- 'gdk-pixbuf2'
- 'glibc'
- 'libnotify'
- 'librsvg'
- 'pango'
- 'python-cairocffi'
- 'python-cffi'
- 'python-xcffib'
- 'python-gobject'
-)
-makedepends=(
- 'git'
- 'jupyter_console'
- 'libpulse'
- 'python-ipykernel'
- 'python-setuptools'
- 'python-setuptools-scm'
-)
-checkdepends=(
- 'graphviz'
- 'imagemagick'
- 'libgnome-keyring'
- 'lm_sensors'
- 'procps-ng'
- 'python-bowler'
- 'python-dbus-next'
- 'python-iwlib'
- 'python-keyring'
- 'python-psutil'
- 'python-pytest'
- 'python-pywlroots'
- 'python-xdg'
- 'python-xvfbwrapper'
- 'xorg-xcalc'
- 'xorg-xclock'
- 'xorg-xeyes'
- 'xorg-server-xephyr'
- 'xorg-xrandr'
- 'xterm'
-)
-optdepends=(
- 'alsa-utils: volume widget'
- 'canto-daemon: canto widget'
- 'cmus: cmus widget'
- 'khal: khal_calendar widget'
- 'libpulse: for pulse_volume and pulseaudio_ffi widget'
- 'lm_sensors: sensors widget'
- 'moc: moc widget'
- 'python-dbus-next: for utils, notifications and several widgets'
- 'python-iwlib: wlan widget'
- 'python-keyring: imapwidget widget'
- 'python-mpd2: mpd2widget widget'
- 'python-psutil: graph, net and memory widget'
- 'python-pywlroots: for experimental wayland support'
- 'python-setproctitle: change process name to qtile'
- 'python-xdg: launchbar widget'
-)
-install="${pkgname}.install"
-source=("git+https://github.com/qtile/qtile#tag=v${pkgver}?signed")
-sha512sums=('SKIP')
-b2sums=('SKIP')
-validpgpkeys=('3CCAB226289DE0160C61BDB418D18F1BC464DCA3') # Tycho Andersen <tycho at tycho.pizza>
-
-
-prepare() {
- cd "${pkgname}"
- # fix issue with imapwidget tests
- # https://github.com/qtile/qtile/issues/2629
- git cherry-pick -n '7ab816f84db3a9982c0ae0006fe0be45b632aa04'
-}
-
-build() {
- cd "${pkgname}"
- python setup.py build
-}
-
-check() {
- local _python_version="$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')"
- local _test_dir='test_dir'
-
- cd "${pkgname}"
-
- # install into test location
- mkdir -vp "${_test_dir}"
- python setup.py install --skip-build \
- --optimize=1 \
- --root="${_test_dir}"
- # create dummy dir for executable and symlink the test executable to it for
- # testing
- mkdir -vp bin
- ln -svf "../${_test_dir}/usr/bin/${pkgname}" "bin/${pkgname}"
-
- export PYTHONPATH="${PWD}/${_test_dir}/usr/lib/python${_python_version}/site-packages/:${PYTHONPATH}"
- export PATH="${PWD}/test_dir/usr/bin:${PATH}"
- export LC_TYPE=en_US.UTF-8
- ./scripts/ffibuild
- # some tests never return: https://github.com/qtile/qtile/issues/2628
- pytest -vv \
- -k "not test_remove"
-}
-
-package() {
- cd "${pkgname}"
- python setup.py install --skip-build \
- --optimize=1 \
- --root="${pkgdir}"
- # license
- install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
- # config
- install -vDm 644 libqtile/resources/default_config.py \
- -t "${pkgdir}/usr/share/doc/${pkgname}/"
- # desktop file
- install -vDm 644 "resources/${pkgname}.desktop" \
- -t "${pkgdir}/usr/share/xsessions/"
- # docs
- install -vDm 644 {CHANGELOG,README.rst} \
- -t "${pkgdir}/usr/share/doc/${pkgname}/"
-}
Copied: qtile/repos/community-x86_64/PKGBUILD (from rev 1016878, qtile/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2021-09-17 18:56:27 UTC (rev 1016879)
@@ -0,0 +1,95 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgname=qtile
+pkgver=0.18.1
+pkgrel=1
+pkgdesc="A full-featured, pure-Python tiling window manager"
+arch=('x86_64')
+url="http://www.qtile.org"
+license=('MIT')
+depends=(
+ 'gdk-pixbuf2'
+ 'glibc'
+ 'libnotify'
+ 'librsvg'
+ 'pango'
+ 'python-cairocffi'
+ 'python-cffi'
+ 'python-xcffib'
+ 'python-gobject'
+)
+makedepends=(
+ 'git'
+ 'libpulse'
+ 'python-setuptools-scm'
+)
+checkdepends=(
+ 'graphviz'
+ 'gtk3'
+ 'imagemagick'
+ 'lm_sensors'
+ 'procps-ng'
+ 'python-bowler'
+ 'python-dbus-next'
+ 'python-gobject'
+ 'python-pytest'
+ 'python-pywlroots'
+ 'python-xdg'
+ 'xorg-server-xephyr'
+ 'xorg-server-xvfb'
+ 'xorg-xrandr'
+)
+optdepends=(
+ 'alsa-utils: for volume widget'
+ 'canto-daemon: for canto widget'
+ 'cmus: for cmus widget'
+ 'jupyter_console: for interaction with qtile via Jupyter'
+ 'khal: for khal_calendar widget'
+ 'libpulse: for pulse_volume and pulseaudio_ffi widget'
+ 'lm_sensors: for sensors widget'
+ 'moc: for moc widget'
+ 'python-dbus-next: for utils, notifications and several widgets'
+ 'python-iwlib: for wlan widget'
+ 'python-keyring: for imapwidget widget'
+ 'python-mpd2: mpd2widget widget'
+ 'python-psutil: graph, net and memory widget'
+ 'python-pywlroots: for experimental wayland support'
+ 'python-setproctitle: change process name to qtile'
+ 'python-xdg: launchbar widget'
+)
+install="${pkgname}.install"
+source=("git+https://github.com/qtile/qtile#tag=v${pkgver}?signed")
+sha512sums=('SKIP')
+b2sums=('SKIP')
+validpgpkeys=(
+ '3CCAB226289DE0160C61BDB418D18F1BC464DCA3' # Tycho Andersen <tycho at tycho.pizza>
+ '35D92E7CC7357A81173EA1C974F9FDD20984FBEC' # Matt Colligan <mcol at posteo.net>
+)
+
+build() {
+ cd "${pkgname}"
+ python setup.py build
+ ./scripts/ffibuild
+}
+
+check() {
+ cd "${pkgname}"
+ export LC_TYPE=en_US.UTF-8
+ pytest -vv --backend x11 --backend wayland
+}
+
+package() {
+ cd "${pkgname}"
+ python setup.py install --optimize=1 --root="${pkgdir}"
+ # license
+ install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
+ # config
+ install -vDm 644 libqtile/resources/default_config.py \
+ -t "${pkgdir}/usr/share/doc/${pkgname}/"
+ # desktop file
+ install -vDm 644 "resources/${pkgname}.desktop" \
+ -t "${pkgdir}/usr/share/xsessions/"
+ # docs
+ install -vDm 644 {CHANGELOG,README.rst} \
+ -t "${pkgdir}/usr/share/doc/${pkgname}/"
+}
Deleted: qtile.install
===================================================================
--- qtile.install 2021-09-17 18:56:18 UTC (rev 1016878)
+++ qtile.install 2021-09-17 18:56:27 UTC (rev 1016879)
@@ -1,10 +0,0 @@
-# arg 1: the new package version
-# arg 2: the old package version
-post_upgrade() {
- if (( "$(vercmp "$2" '0.17.0-1')" < 0 )); then
- printf "WARNING: Major config and functionality changes. A restart (not reload) of qtile is required.\n"
- fi
- if (( "$(vercmp "$2" '0.18.0-1')" < 0 )); then
- printf "WARNING: Major config changes. Make sure to read /usr/share/doc/qtile/CHANGELOG.\n"
- fi
-}
Copied: qtile/repos/community-x86_64/qtile.install (from rev 1016878, qtile/trunk/qtile.install)
===================================================================
--- qtile.install (rev 0)
+++ qtile.install 2021-09-17 18:56:27 UTC (rev 1016879)
@@ -0,0 +1,10 @@
+# arg 1: the new package version
+# arg 2: the old package version
+post_upgrade() {
+ if (( "$(vercmp "$2" '0.17.0-1')" < 0 )); then
+ printf "WARNING: Major config and functionality changes. A restart (not reload) of qtile is required.\n"
+ fi
+ if (( "$(vercmp "$2" '0.18.0-1')" < 0 )); then
+ printf "WARNING: Major config changes. Make sure to read /usr/share/doc/qtile/CHANGELOG.\n"
+ fi
+}
More information about the arch-commits
mailing list