[arch-commits] Commit in imlib2/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Felix Yan]

    Date: Monday, September 20, 2021 @ 20:52:45
  Author: felixonmars
Revision: 424441

archrelease: copy trunk to testing-x86_64

Added:
  imlib2/repos/testing-x86_64/
  imlib2/repos/testing-x86_64/PKGBUILD
    (from rev 424440, imlib2/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: imlib2/repos/testing-x86_64/PKGBUILD (from rev 424440, imlib2/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-09-20 20:52:45 UTC (rev 424441)
@@ -0,0 +1,48 @@
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Contributor: Arjan Timmerman <arjan.archlinux.org>
+# Contributor: Tom Newsom <Jeepster.gmx.co.uk>
+
+pkgname=imlib2
+pkgver=1.7.4
+pkgrel=1
+pkgdesc="Library that does image file loading and saving as well as rendering, manipulation, arbitrary polygon support"
+url="https://sourceforge.net/projects/enlightenment/"
+arch=('x86_64')
+license=('BSD')
+depends=('libtiff' 'giflib' 'bzip2' 'freetype2' 'libxext' 'libpng' 'libid3tag' 'libjpeg-turbo' 'libwebp')
+source=(https://downloads.sourceforge.net/enlightenment/$pkgname-$pkgver.tar.bz2)
+sha512sums=('54c213de38535f14359d9e407b9ae5911a158347525a298673ba53d122c3e506449feb34203e764e43d5aa163f3024093803cd976a23c0f0f65b843ed9685d66')
+
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  sed -i 's/@my_libs@//' imlib2-config.in
+}
+
+
+build() {
+  cd "${pkgname}-${pkgver}"
+
+  [ $CARCH = "i686" ] && EXTRAOPTS="--enable-mmx"
+  [ $CARCH = "x86_64" ] && EXTRAOPTS="--enable-amd64"
+
+  ./configure --prefix=/usr \
+              --sysconfdir=/etc/imlib2 \
+              --x-libraries=/usr/lib $EXTRAOPTS
+  make
+}
+
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  make check
+}
+
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+
+  # Install License
+  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+}