[arch-commits] Commit in htop/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Christian Hesse eworm at gemini.archlinux.org
Tue Sep 21 07:00:05 UTC 2021


    Date: Tuesday, September 21, 2021 @ 07:00:05
  Author: eworm
Revision: 424451

archrelease: copy trunk to testing-x86_64

Added:
  htop/repos/testing-x86_64/
  htop/repos/testing-x86_64/PKGBUILD
    (from rev 424450, htop/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: htop/repos/testing-x86_64/PKGBUILD (from rev 424450, htop/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-09-21 07:00:05 UTC (rev 424451)
@@ -0,0 +1,49 @@
+# Maintainer: Christian Hesse <mail at eworm.de>
+# Maintainer: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=htop
+_tag='a8637afe0398f0be0131f73563b55ef9315ca351' # git rev-parse ${pkgver}
+pkgver=3.1.0
+pkgrel=1
+pkgdesc='Interactive process viewer'
+arch=('x86_64')
+url='https://htop.dev/'
+license=('GPL')
+depends=('libcap' 'libcap.so' 'libnl' 'ncurses' 'libncursesw.so')
+makedepends=('git' 'lm_sensors')
+optdepends=('lm_sensors: show cpu temperatures'
+            'lsof: show files opened by a process'
+            'strace: attach to a running process')
+options=('!emptydirs')
+validpgpkeys=('F7ABE8761E6FE68638E6283AFE0842EE36DD8C0C') # Nathan Scott <nathans at debian.org>
+source=("git+https://github.com/htop-dev/htop.git#tag=${_tag}?signed")
+sha256sums=('SKIP')
+
+prepare() {
+  cd "${pkgname}"
+
+  autoreconf -fi
+}
+
+build() {
+  cd "${pkgname}"
+
+  ./configure \
+      --prefix=/usr \
+      --sysconfdir=/etc \
+      --enable-cgroup \
+      --enable-delayacct \
+      --enable-openvz \
+      --enable-unicode \
+      --enable-vserver
+
+  make
+}
+
+package() {
+  cd "${pkgname}"
+
+  make DESTDIR="${pkgdir}" install
+}



More information about the arch-commits mailing list