[arch-commits] Commit in libcurl/repos (2 files)
Christian Hesse
eworm at gemini.archlinux.org
Wed Sep 22 06:46:51 UTC 2021
Date: Wednesday, September 22, 2021 @ 06:46:51
Author: eworm
Revision: 1021363
archrelease: copy trunk to community-testing-x86_64
Added:
libcurl/repos/community-testing-x86_64/
libcurl/repos/community-testing-x86_64/PKGBUILD
(from rev 1021362, libcurl/trunk/PKGBUILD)
----------+
PKGBUILD | 92 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 92 insertions(+)
Copied: libcurl/repos/community-testing-x86_64/PKGBUILD (from rev 1021362, libcurl/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2021-09-22 06:46:51 UTC (rev 1021363)
@@ -0,0 +1,92 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Piotr Balcerowski <piotr at balcerowski.org>
+
+pkgbase=libcurl
+pkgname=(libcurl-compat libcurl-gnutls)
+_pkgname=curl
+pkgver=7.79.1
+pkgrel=1
+pkgdesc='An URL retrieval library'
+arch=('x86_64')
+url='https://curl.haxx.se'
+license=('MIT')
+depends=("${_pkgname}")
+makedepends=('gnutls' 'openssl')
+options=('strip')
+source=("https://curl.haxx.se/download/curl-${pkgver}.tar.gz"{,.asc})
+sha512sums=('0f9546285bef741f69d25f20bcd5b961d29fc88084d9f3ebe0c66a6674f4c69a531b41f8e3cc57474f528abdd90aa7981e653c339c5e8383353c36a82efaafc4'
+ 'SKIP')
+validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg
+
+_configure_options=(
+ --prefix='/usr'
+ --disable-ldap
+ --disable-ldaps
+ --disable-manual
+ --disable-versioned-symbols
+ --enable-ipv6
+ --enable-threaded-resolver
+ --with-gssapi
+ --with-libssh2
+ --with-openssl
+ --with-random='/dev/urandom'
+ --with-ca-bundle='/etc/ssl/certs/ca-certificates.crt'
+)
+
+build() {
+ mkdir build-{compat,gnutls}
+
+ # build compat (disable-versioned-symbols)
+ cd "${srcdir}"/build-compat
+
+ "${srcdir}/curl-${pkgver}"/configure \
+ "${_configure_options[@]}"
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make -C lib
+
+ # build gnutls (without-ssl)
+ cd "${srcdir}"/build-gnutls
+
+ "${srcdir}/curl-${pkgver}"/configure \
+ "${_configure_options[@]}" \
+ --without-ssl \
+ --with-gnutls='/usr'
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make -C lib
+}
+
+package_libcurl-compat() {
+ pkgdesc='An URL retrieval library (without versioned symbols)'
+ depends+=('openssl')
+
+ cd "${srcdir}"/build-compat
+
+ make -C lib DESTDIR="${pkgdir}" install
+
+ mv "${pkgdir}"/usr/lib/libcurl{,-compat}.so.4.7.0
+ rm "${pkgdir}"/usr/lib/libcurl.{a,so}*
+ for version in 3 4.0.0 4.1.0 4.2.0 4.3.0 4.4.0 4.5.0 4.6.0; do
+ ln -s libcurl-compat.so.4.7.0 "${pkgdir}"/usr/lib/libcurl.so.${version}
+ done
+
+ install -dm 755 "${pkgdir}"/usr/share/licenses
+ ln -s curl "${pkgdir}"/usr/share/licenses/libcurl-compat
+}
+
+package_libcurl-gnutls() {
+ pkgdesc='An URL retrieval library (without versioned symbols and linked against gnutls)'
+ depends+=('gnutls')
+
+ cd "${srcdir}"/build-gnutls
+
+ make -C lib DESTDIR="${pkgdir}" install
+
+ mv "${pkgdir}"/usr/lib/libcurl{,-gnutls}.so.4.7.0
+ rm "${pkgdir}"/usr/lib/libcurl.{a,so}*
+ for version in 3 4 4.0.0 4.1.0 4.2.0 4.3.0 4.4.0 4.5.0 4.6.0; do
+ ln -s libcurl-gnutls.so.4.7.0 "${pkgdir}"/usr/lib/libcurl-gnutls.so.${version}
+ done
+
+ install -dm 755 "${pkgdir}"/usr/share/licenses
+ ln -s curl "${pkgdir}"/usr/share/licenses/libcurl-gnutls
+}
More information about the arch-commits
mailing list