[arch-commits] Commit in waybar/repos (2 files)

[Antonio Rojas]

    Date: Wednesday, September 29, 2021 @ 20:17:17
  Author: arojas
Revision: 1026003

archrelease: copy trunk to community-testing-x86_64

Added:
  waybar/repos/community-testing-x86_64/
  waybar/repos/community-testing-x86_64/PKGBUILD
    (from rev 1026002, waybar/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: waybar/repos/community-testing-x86_64/PKGBUILD (from rev 1026002, waybar/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-09-29 20:17:17 UTC (rev 1026003)
@@ -0,0 +1,57 @@
+# Maintainer: Brett Cornwall <ainola at archlinux.org>
+# Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
+
+pkgname=waybar
+pkgver=0.9.8
+pkgrel=2
+pkgdesc='Highly customizable Wayland bar for Sway and Wlroots based compositors'
+arch=('x86_64')
+url="https://github.com/Alexays/Waybar/"
+license=('MIT')
+depends=(
+    'gtkmm3'
+    'libjsoncpp.so'
+    'libsigc++'
+    'fmt'
+    'wayland'
+    'libdate-tz.so'
+    'libspdlog.so'
+    'gtk-layer-shell'
+    'libevdev'
+    'libpulse'
+    'libnl'
+    'libappindicator-gtk3'
+    'libdbusmenu-gtk3'
+    'libmpdclient'
+    'libsndio.so'
+    'libxkbcommon'
+)
+makedepends=(
+    'cmake'
+    'meson'
+    'scdoc' # For generating manpages
+    'wayland-protocols'
+)
+optdepends=(
+    'otf-font-awesome: Icons in the default configuration'
+)
+source=(
+    "$pkgname-$pkgver.tar.gz::https://github.com/Alexays/Waybar/archive/$pkgver.tar.gz"
+)
+sha256sums=('3f067c484aaee3e7d8ded382e72c280a92913b0c4e8a20d0ac9afdf8baf19405')
+
+build() {
+    cd "Waybar-$pkgver"
+    meson --prefix=/usr \
+          --buildtype=plain \
+          --auto-features=enabled \
+          --wrap-mode=nodownload \
+          build
+    ninja -C build
+}
+
+package() {
+    cd "Waybar-$pkgver"
+    DESTDIR="$pkgdir" ninja -C build install
+    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+}