[arch-commits] Commit in rygel/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Thursday, September 30, 2021 @ 19:59:18
  Author: heftig
Revision: 424922

archrelease: copy trunk to extra-x86_64

Added:
  rygel/repos/extra-x86_64/PKGBUILD
    (from rev 424920, rygel/trunk/PKGBUILD)
Deleted:
  rygel/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   96 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 48 insertions(+), 48 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-09-30 19:59:17 UTC (rev 424921)
+++ PKGBUILD	2021-09-30 19:59:18 UTC (rev 424922)
@@ -1,48 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Balló György <ballogyor+arch at gmail dot com>
-
-pkgname=rygel
-pkgver=0.40.1
-pkgrel=1
-epoch=1
-pkgdesc="UPnP AV MediaServer and MediaRenderer"
-url="https://wiki.gnome.org/Projects/Rygel"
-arch=(x86_64)
-license=(LGPL)
-depends=(gupnp gupnp-av gupnp-dlna libgee gtk3 libunistring tracker3
-         libmediaart gst-editing-services)
-makedepends=(vala gobject-introspection git meson)
-optdepends=('gst-plugins-base: Extra media codecs'
-            'gst-plugins-good: Extra media codecs'
-            'gst-plugins-bad: Extra media codecs'
-            'gst-plugins-ugly: Extra media codecs'
-            'gst-libav: Extra media codecs'
-            'tracker3-miners: Share indexed media files')
-backup=(etc/rygel.conf)
-groups=(gnome)
-_commit=7b2c10d415616d470e7698020bbfe35e2bb21529  # tags/rygel-0.40.1^0
-source=("git+https://gitlab.gnome.org/GNOME/rygel.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/^RYGEL//;s/^rygel-//;s/_/./g;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-}
-
-build() {
-  arch-meson $pkgname build \
-    -D plugins=external,gst-launch,lms,media-export,mpris,playbin,ruih,tracker3
-  meson compile -C build
-}
-
-check() {
-  meson test -C build --print-errorlogs
-}
-
-package() {
-  DESTDIR="$pkgdir" meson install -C build
-}

Copied: rygel/repos/extra-x86_64/PKGBUILD (from rev 424920, rygel/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-09-30 19:59:18 UTC (rev 424922)
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=rygel
+pkgver=0.40.2
+pkgrel=1
+epoch=1
+pkgdesc="UPnP AV MediaServer and MediaRenderer"
+url="https://wiki.gnome.org/Projects/Rygel"
+arch=(x86_64)
+license=(LGPL)
+depends=(gupnp gupnp-av gupnp-dlna libgee gtk3 libunistring tracker3
+         libmediaart gst-editing-services)
+makedepends=(vala gobject-introspection git meson)
+optdepends=('gst-plugins-base: Extra media codecs'
+            'gst-plugins-good: Extra media codecs'
+            'gst-plugins-bad: Extra media codecs'
+            'gst-plugins-ugly: Extra media codecs'
+            'gst-libav: Extra media codecs'
+            'tracker3-miners: Share indexed media files')
+backup=(etc/rygel.conf)
+groups=(gnome)
+_commit=4cc71529e53acaae16957d38a6565396a7ebf6b4  # tags/rygel-0.40.2^0
+source=("git+https://gitlab.gnome.org/GNOME/rygel.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^RYGEL//;s/^rygel-//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  git cherry-pick -n d0410cccf6af55e16d3ba9400ad5e9f703313739
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}