[arch-commits] Commit in wayland/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Friday, April 1, 2022 @ 18:29:02
  Author: heftig
Revision: 441165

archrelease: copy trunk to testing-x86_64

Added:
  wayland/repos/testing-x86_64/
  wayland/repos/testing-x86_64/PKGBUILD
    (from rev 441164, wayland/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: wayland/repos/testing-x86_64/PKGBUILD (from rev 441164, wayland/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-04-01 18:29:02 UTC (rev 441165)
@@ -0,0 +1,49 @@
+# Maintainer: Sébastien Luttringer <seblu at archlinux.org>
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: Joel Teichroeb <joel at teichroeb.net>
+
+pkgbase=wayland
+pkgname=(wayland wayland-docs)
+pkgver=1.20.0
+pkgrel=2
+pkgdesc='A computer display server protocol'
+arch=('x86_64')
+url='https://wayland.freedesktop.org/'
+license=('MIT')
+depends=('glibc' 'libffi' 'expat' 'libxml2')
+makedepends=('meson' 'libxslt' 'doxygen' 'xmlto' 'graphviz' 'docbook-xsl')
+options=('debug')
+validpgpkeys=('C7223EBE4EF66513B892598911A30156E0E67611'  # Bryce Harrington
+              'C0066D7DB8E9AC6844D728715E54498E697F11D7'  # Derek Foreman
+              '34FF9526CFEF0E97A340E2E40FDE7BE0E88F5E48') # emersion <contact at emersion.fr>
+source=("https://wayland.freedesktop.org/releases/$pkgbase-$pkgver.tar.xz"{,.sig})
+sha256sums=('b8a034154c7059772e0fdbd27dbfcda6c732df29cae56a82274f6ec5d7cd8725'
+            'SKIP')
+
+build() {
+  arch-meson $pkgbase-$pkgver build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package_wayland() {
+  provides=(libwayland-{client,cursor,egl,server}.so)
+
+  meson install -C build --destdir "$pkgdir"
+  mkdir -p docs/share
+  mv "$pkgdir"/usr/share/{doc,man} docs/share
+  install -Dm 644 $pkgbase-$pkgver/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}
+
+package_wayland-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+
+  mv docs "$pkgdir/usr"
+  install -Dm 644 $pkgbase-$pkgver/COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}
+
+# vim:set ts=2 sw=2 et: