[arch-commits] Commit in gnome-settings-daemon/repos (2 files)

[Jan Steffens]

    Date: Saturday, April 2, 2022 @ 13:34:20
  Author: heftig
Revision: 441246

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-settings-daemon/repos/gnome-unstable-x86_64/
  gnome-settings-daemon/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 441245, gnome-settings-daemon/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: gnome-settings-daemon/repos/gnome-unstable-x86_64/PKGBUILD (from rev 441245, gnome-settings-daemon/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2022-04-02 13:34:20 UTC (rev 441246)
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=gnome-settings-daemon
+pkgver=42.1
+pkgrel=1
+pkgdesc="GNOME Settings Daemon"
+url="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gnome-desktop gsettings-desktop-schemas libcanberra-pulse
+         libnotify systemd libwacom pulseaudio pulseaudio-alsa upower librsvg
+         libgweather-4 geocode-glib geoclue nss libgudev gtk3 libnm gcr)
+makedepends=(libxslt docbook-xsl python git meson usbguard)
+checkdepends=(python-gobject python-dbusmock)
+optdepends=('usbguard: USB protection support')
+groups=(gnome)
+backup=(etc/xdg/Xwayland-session.d/00-xrdb)
+_commit=946e4bbea6cc078776901459dc69fd65888b2a16  # tags/42.1^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-settings-daemon.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}