[arch-commits] Commit in gnome-bluetooth-3.0/trunk (PKGBUILD)
Jan Steffens
heftig at gemini.archlinux.org
Sat Apr 2 14:24:25 UTC 2022
Date: Saturday, April 2, 2022 @ 14:24:24
Author: heftig
Revision: 441263
42.0-1
Added:
gnome-bluetooth-3.0/trunk/PKGBUILD
----------+
PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 44 insertions(+)
Added: PKGBUILD
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2022-04-02 14:24:24 UTC (rev 441263)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Roman Kyrylych <roman at archlinux.org>
+
+pkgname=gnome-bluetooth-3.0
+pkgver=42.0
+pkgrel=1
+pkgdesc="The GNOME Bluetooth Subsystem"
+url="https://wiki.gnome.org/Projects/GnomeBluetooth"
+arch=(x86_64)
+license=(GPL LGPL)
+depends=(gtk4 libadwaita libnotify bluez gsound systemd pulseaudio-bluetooth
+ upower)
+makedepends=(gobject-introspection gtk-doc docbook-xsl git meson)
+checkdepends=(python-dbusmock)
+provides=(libgnome-bluetooth{,-ui}-3.0.so)
+options=(debug)
+_commit=fc488724cc543af991fb0c2c5677c58207369aaa # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-bluetooth.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd gnome-bluetooth
+ git describe --tags | sed 's/^GNOMEBT_V_//;s/_fixed//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+ cd gnome-bluetooth
+}
+
+build() {
+ arch-meson gnome-bluetooth build -D gtk_doc=true
+ meson compile -C build
+}
+
+check() {
+ meson test -C build --print-errorlogs
+}
+
+package() {
+ meson install -C build --destdir "$pkgdir"
+}
+
+# vim:set sw=2 et:
More information about the arch-commits
mailing list