[arch-commits] Commit in gnome-control-center/repos (2 files)
Jan Steffens
heftig at gemini.archlinux.org
Sat Apr 2 17:37:56 UTC 2022
Date: Saturday, April 2, 2022 @ 17:37:55
Author: heftig
Revision: 441283
archrelease: copy trunk to gnome-unstable-x86_64
Added:
gnome-control-center/repos/gnome-unstable-x86_64/
gnome-control-center/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 441282, gnome-control-center/trunk/PKGBUILD)
----------+
PKGBUILD | 61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 61 insertions(+)
Copied: gnome-control-center/repos/gnome-unstable-x86_64/PKGBUILD (from rev 441282, gnome-control-center/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2022-04-02 17:37:55 UTC (rev 441283)
@@ -0,0 +1,61 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-control-center
+pkgver=42.0
+pkgrel=1
+pkgdesc="GNOME's main interface to configure various aspects of the desktop"
+url="https://gitlab.gnome.org/GNOME/gnome-control-center"
+license=(GPL2)
+arch=(x86_64)
+depends=(accountsservice cups-pk-helper gnome-bluetooth-3.0 gnome-desktop-4
+ gnome-online-accounts gnome-settings-daemon gsettings-desktop-schemas
+ gtk4 libgtop libnma-gtk4 sound-theme-freedesktop upower libpwquality
+ gnome-color-manager smbclient libmm-glib libgnomekbd libibus libgudev
+ bolt udisks2 libadwaita gsound colord-gtk4 gcr)
+makedepends=(docbook-xsl modemmanager git python meson)
+checkdepends=(python-dbusmock python-gobject xorg-server-xvfb)
+optdepends=('system-config-printer: Printer settings'
+ 'gnome-user-share: WebDAV file sharing'
+ 'gnome-remote-desktop: screen sharing'
+ 'rygel: media sharing'
+ 'openssh: remote login'
+ 'power-profiles-daemon: Power profiles support')
+groups=(gnome)
+options=(debug)
+_commit=6199d4058e1d958533569995762b80073abebf17 # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-control-center.git#commit=$_commit"
+ "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+
+ # Install bare logos into pixmaps, not icons
+ sed -i "/install_dir/s/'icons'/'pixmaps'/" panels/info-overview/meson.build
+
+ git submodule init subprojects/gvc
+ git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+ git submodule update
+}
+
+
+build() {
+ arch-meson $pkgname build -D documentation=true
+ meson compile -C build
+}
+
+check() {
+ meson test -C build --print-errorlogs
+}
+
+package() {
+ meson install -C build --destdir "$pkgdir"
+ install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
+}
More information about the arch-commits
mailing list