[arch-commits] Commit in gnome-shell/repos (2 files)

[Jan Steffens]

    Date: Saturday, April 2, 2022 @ 17:44:55
  Author: heftig
Revision: 441289

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-shell/repos/gnome-unstable-x86_64/
  gnome-shell/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 441288, gnome-shell/trunk/PKGBUILD)

----------+
 PKGBUILD |   68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

Copied: gnome-shell/repos/gnome-unstable-x86_64/PKGBUILD (from rev 441288, gnome-shell/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2022-04-02 17:44:55 UTC (rev 441289)
@@ -0,0 +1,68 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Flamelab <panosfilip at gmail.com
+
+pkgname=gnome-shell
+pkgver=42.0
+pkgrel=1
+epoch=1
+pkgdesc="Next generation desktop shell"
+url="https://wiki.gnome.org/Projects/GnomeShell"
+arch=(x86_64)
+license=(GPL)
+depends=(accountsservice gcr gjs gnome-bluetooth-3.0 upower gnome-session gtk4
+         gnome-settings-daemon gsettings-desktop-schemas libcanberra-pulse
+         libgdm libsecret mutter libnma unzip gstreamer libibus gnome-autoar
+         gnome-disk-utility gst-plugin-pipewire libsoup3 libgweather-4)
+makedepends=(gtk-doc gnome-control-center evolution-data-server
+             gobject-introspection git meson sassc asciidoc bash-completion)
+checkdepends=(xorg-server-xvfb)
+optdepends=('gnome-control-center: System settings'
+            'evolution-data-server: Evolution calendar integration')
+groups=(gnome)
+options=(debug)
+_commit=44b4b02c3f772a50e6f8b8fd2dca6d9dc3a98725  # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd gnome-shell
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd gnome-shell
+
+  git submodule init
+  git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+
+build() {
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+
+  arch-meson gnome-shell build -D gtk_doc=true
+  meson compile -C build
+}
+
+_check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  export XDG_RUNTIME_DIR
+
+  meson test -C build --print-errorlogs
+)
+
+check() {
+  dbus-run-session xvfb-run -s '-nolisten local +iglx -noreset' \
+    bash -c "$(declare -f _check); _check"
+}
+
+package() {
+  depends+=(libmutter-10.so)
+  meson install -C build --destdir "$pkgdir"
+}
+
+# vim:set sw=2 et: