[arch-commits] Commit in eog/repos (2 files)

[Jan Steffens]

    Date: Saturday, April 2, 2022 @ 18:30:18
  Author: heftig
Revision: 441293

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  eog/repos/gnome-unstable-x86_64/
  eog/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 441292, eog/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: eog/repos/gnome-unstable-x86_64/PKGBUILD (from rev 441292, eog/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2022-04-02 18:30:18 UTC (rev 441293)
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=eog
+pkgname=(eog eog-docs)
+pkgver=42.0
+pkgrel=1
+pkgdesc="Eye of Gnome: An image viewing and cataloging program"
+url="https://wiki.gnome.org/Apps/EyeOfGnome"
+arch=(x86_64)
+license=(GPL)
+depends=(gnome-desktop libexif lcms2 exempi libpeas librsvg libhandy)
+makedepends=(gobject-introspection gi-docgen git meson yelp-tools systemd)
+options=(debug)
+_commit=5f69aab265be3b28d85b1e9d363d63e3bc568945  # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/eog.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd eog
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+build() {
+  arch-meson eog build -D gtk_doc=true -D libportal=false
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package_eog() {
+  optdepends=('eog-plugins: Additional features')
+  groups=(gnome)
+
+  meson install -C build --destdir "$pkgdir"
+
+  mkdir -p doc/usr/share
+  mv {"$pkgdir",doc}/usr/share/gtk-doc
+}
+
+package_eog-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+
+  mv doc/* "$pkgdir"
+}