[arch-commits] Commit in evolution/repos (2 files)

[Jan Steffens]

    Date: Saturday, April 2, 2022 @ 19:02:46
  Author: heftig
Revision: 441311

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  evolution/repos/gnome-unstable-x86_64/
  evolution/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 441308, evolution/trunk/PKGBUILD)

----------+
 PKGBUILD |   84 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 84 insertions(+)

Copied: evolution/repos/gnome-unstable-x86_64/PKGBUILD (from rev 441308, evolution/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2022-04-02 19:02:46 UTC (rev 441311)
@@ -0,0 +1,84 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Fabian Bornschein <fabiscafe-cat-mailbox-dog-org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=evolution
+pkgname=(evolution evolution-bogofilter evolution-spamassassin)
+pkgver=3.44.0
+pkgrel=1
+pkgdesc="Manage your email, contacts and schedule"
+url="https://wiki.gnome.org/Apps/Evolution"
+arch=(x86_64)
+license=(GPL)
+depends=(gnome-desktop evolution-data-server libcanberra libpst libytnef gspell
+         libcryptui gnome-autoar libgweather-4 enchant cmark)
+makedepends=(intltool itstool docbook-xsl networkmanager bogofilter
+             spamassassin highlight gtk-doc yelp-tools git cmake ninja)
+options=(!emptydirs debug)
+_commit=0839b6f5b459b2fdd79e1fcf385b8d5c7759135f  # tags/3.44.0^0
+source=("git+https://gitlab.gnome.org/GNOME/evolution.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+
+  # https://gitlab.gnome.org/GNOME/evolution/-/issues/1835
+  # Mail: Preview uses wrong colors for HTML mail with dark theme
+  git cherry-pick -n dea447327f92ea1617f1f852658326dc8852e721
+}
+
+build() {
+  cmake -S $pkgbase -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DLIBEXEC_INSTALL_DIR=/usr/lib \
+    -DSYSCONF_INSTALL_DIR=/etc \
+    -DENABLE_SMIME=ON \
+    -DENABLE_GTK_DOC=ON \
+    -DWITH_GWEATHER4=ON
+  cmake --build build
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_evolution() {
+  depends+=(libcamel-1.2.so libebook-1.2.so libebook-contacts-1.2.so
+            libecal-2.0.so libedataserver-1.2.so libedataserverui-1.2.so)
+  optdepends=('highlight: text highlight plugin'
+              'evolution-spamassassin: Spamassassin spam check plugin'
+              'evolution-bogofilter: Bogofilter spam check plugin')
+  groups=(gnome-extra)
+
+  DESTDIR="$pkgdir" cmake --install build
+
+  cd "$pkgdir"
+  for x in bogofilter spamassassin; do
+    _pick $x usr/lib/evolution/modules/module-$x.so
+    _pick $x usr/share/metainfo/org.gnome.Evolution-$x.metainfo.xml
+  done
+}
+
+
+package_evolution-bogofilter() {
+  pkgdesc="Spam filtering for Evolution, using Bogofilter"
+  depends=("evolution=$pkgver" bogofilter)
+  mv bogofilter/* "$pkgdir"
+}
+
+package_evolution-spamassassin() {
+  pkgdesc="Spam filtering for Evolution, using SpamAssassin"
+  depends=("evolution=$pkgver" spamassassin)
+  mv spamassassin/* "$pkgdir"
+}