[arch-commits] Commit in gedit/repos (2 files)

[Jan Steffens]

    Date: Saturday, April 2, 2022 @ 19:07:19
  Author: heftig
Revision: 441315

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gedit/repos/gnome-unstable-x86_64/
  gedit/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 441313, gedit/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: gedit/repos/gnome-unstable-x86_64/PKGBUILD (from rev 441313, gedit/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2022-04-02 19:07:19 UTC (rev 441315)
@@ -0,0 +1,50 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gedit
+pkgver=42.0
+pkgrel=1
+pkgdesc="GNOME Text Editor"
+url="https://wiki.gnome.org/Apps/Gedit"
+arch=(x86_64)
+license=(GPL)
+depends=(gtksourceview4 gsettings-desktop-schemas libpeas gspell python-gobject)
+makedepends=(yelp-tools vala gobject-introspection git gtk-doc meson
+             appstream-glib desktop-file-utils libxml2)
+optdepends=('gedit-plugins: Additional features')
+conflicts=('gedit-code-assistance<=3.16.0+4+gd19b879-1')
+groups=(gnome)
+options=(debug)
+_commit=61f737bce27b18335388c51060cc9fad0bb48154  # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gedit.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd gedit
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd gedit
+
+  git submodule init
+  git submodule set-url subprojects/libgd "$srcdir/libgd"
+  git submodule update
+}
+
+build() {
+  arch-meson gedit build \
+    -D gtk_doc=true \
+    -D require_all_tests=true
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}