[arch-commits] Commit in gtksourceview5/repos (extra-x86_64 extra-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Saturday, April 2, 2022 @ 19:15:52
  Author: heftig
Revision: 441318

archrelease: copy trunk to extra-x86_64

Added:
  gtksourceview5/repos/extra-x86_64/
  gtksourceview5/repos/extra-x86_64/PKGBUILD
    (from rev 441317, gtksourceview5/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: gtksourceview5/repos/extra-x86_64/PKGBUILD (from rev 441317, gtksourceview5/trunk/PKGBUILD)
===================================================================
--- extra-x86_64/PKGBUILD	                        (rev 0)
+++ extra-x86_64/PKGBUILD	2022-04-02 19:15:52 UTC (rev 441318)
@@ -0,0 +1,56 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgbase=gtksourceview5
+pkgname=(gtksourceview5 gtksourceview5-docs)
+pkgver=5.4.0
+pkgrel=1
+pkgdesc="A text widget adding syntax highlighting and more to GNOME"
+url="https://wiki.gnome.org/Projects/GtkSourceView"
+arch=(x86_64)
+license=(LGPL)
+depends=(gtk4 libxml2 pcre2)
+makedepends=(gobject-introspection vala gi-docgen git meson)
+checkdepends=(xorg-server-xvfb)
+options=(debug)
+_commit=785a794811bc48505fa1c2c7b970ca2203cf759a  # tags/5.4.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gtksourceview.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd gtksourceview
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd gtksourceview
+}
+
+build() {
+  arch-meson gtksourceview build -D gtk_doc=true
+  meson compile -C build
+}
+
+check() {
+  dbus-run-session xvfb-run -s '-nolisten local' \
+    meson test -C build --print-errorlogs
+}
+
+package_gtksourceview5() {
+  provides=(libgtksourceview-${pkgver%%.*}.so)
+
+  meson install -C build --destdir "$pkgdir"
+
+  mkdir -p doc/usr/share
+  mv {"$pkgdir",doc}/usr/share/doc
+}
+
+package_gtksourceview5-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+
+  mv doc/* "$pkgdir"
+}
+
+# vim:set sw=2 et: