[arch-commits] Commit in gnome-music/repos (2 files)

[Jan Steffens]

    Date: Saturday, April 2, 2022 @ 22:15:21
  Author: heftig
Revision: 441335

archrelease: copy trunk to gnome-unstable-any

Added:
  gnome-music/repos/gnome-unstable-any/
  gnome-music/repos/gnome-unstable-any/PKGBUILD
    (from rev 441334, gnome-music/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: gnome-music/repos/gnome-unstable-any/PKGBUILD (from rev 441334, gnome-music/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-any/PKGBUILD	                        (rev 0)
+++ gnome-unstable-any/PKGBUILD	2022-04-02 22:15:21 UTC (rev 441335)
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-music
+pkgver=42.0
+pkgrel=1
+epoch=1
+pkgdesc="Music player and management application"
+url="https://wiki.gnome.org/Apps/Music"
+arch=(any)
+license=(GPL)
+depends=(grilo grilo-plugins tracker3-miners libdmapsharing libmediaart gtk4
+         gvfs python-gobject python-cairo gst-plugins-base python-requests
+         libadwaita)
+makedepends=(gobject-introspection git meson yelp-tools appstream-glib)
+optdepends=('gst-plugins-good: Extra media codecs'
+            'gst-plugins-ugly: Extra media codecs'
+            'gst-plugins-bad: Extra media codecs'
+            'gst-libav: Extra media codecs')
+groups=(gnome)
+_commit=52a43cca73b7bd5ed4facedf0994daeee1fb3b89  # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-music.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+
+  python -m compileall -d /usr/lib "$pkgdir/usr/lib"
+  python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
+}