[arch-commits] Commit in gnome-shell-extensions/repos (2 files)
Jan Steffens
heftig at gemini.archlinux.org
Sat Apr 2 22:27:10 UTC 2022
Date: Saturday, April 2, 2022 @ 22:27:09
Author: heftig
Revision: 441340
archrelease: copy trunk to gnome-unstable-any
Added:
gnome-shell-extensions/repos/gnome-unstable-any/
gnome-shell-extensions/repos/gnome-unstable-any/PKGBUILD
(from rev 441339, gnome-shell-extensions/trunk/PKGBUILD)
----------+
PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 44 insertions(+)
Copied: gnome-shell-extensions/repos/gnome-unstable-any/PKGBUILD (from rev 441339, gnome-shell-extensions/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-any/PKGBUILD (rev 0)
+++ gnome-unstable-any/PKGBUILD 2022-04-02 22:27:09 UTC (rev 441340)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=gnome-shell-extensions
+pkgver=42.0
+pkgrel=1
+pkgdesc="Extensions for GNOME shell, including classic mode"
+url="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
+arch=(any)
+license=(GPL)
+depends=(gnome-shell)
+makedepends=(meson git sassc)
+optdepends=('gnome-menus: applications menu extension')
+groups=(gnome)
+_commit=227c900d1c037dd991cf74caafdc55ecf9139993 # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell-extensions.git#commit=$_commit"
+ "git+https://gitlab.gnome.org/GNOME/gnome-shell-sass.git")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+
+ git submodule init
+ git submodule set-url data/gnome-shell-sass "$srcdir/gnome-shell-sass"
+ git submodule update
+}
+
+build() {
+ arch-meson $pkgname build -D extension_set=all -D classic_mode=true
+ meson compile -C build
+}
+
+check() {
+ meson test -C build --print-errorlogs
+}
+
+package() {
+ meson install -C build --destdir "$pkgdir"
+}
More information about the arch-commits
mailing list