[arch-commits] Commit in gnome-remote-desktop/repos (2 files)

[Jan Steffens]

    Date: Saturday, April 2, 2022 @ 22:58:03
  Author: heftig
Revision: 441345

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-remote-desktop/repos/gnome-unstable-x86_64/
  gnome-remote-desktop/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 441344, gnome-remote-desktop/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: gnome-remote-desktop/repos/gnome-unstable-x86_64/PKGBUILD (from rev 441344, gnome-remote-desktop/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2022-04-02 22:58:03 UTC (rev 441345)
@@ -0,0 +1,60 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=gnome-remote-desktop
+pkgver=42.0
+pkgrel=1
+pkgdesc="GNOME Remote Desktop server"
+url="https://wiki.gnome.org/Projects/Mutter/RemoteDesktop"
+arch=(x86_64)
+license=(GPL2)
+depends=(cairo freerdp glib2 pipewire systemd libvncserver libsecret libnotify
+         dconf fuse3 libxkbcommon libepoxy)
+makedepends=(git meson ffnvcodec-headers)
+checkdepends=(xorg-server-xvfb python-dbus python-gobject mutter wireplumber)
+groups=(gnome)
+options=(debug)
+_commit=252f495a0f23ca25056cc5815587255614ffdfc7  # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-remote-desktop.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+_check() (
+  mkdir -p -m 700 "${XDG_CONFIG_HOME:=$PWD/config-dir}"
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/src}"
+  export XDG_CONFIG_HOME XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  export GSETTINGS_BACKEND=keyfile
+  gsettings set org.gnome.desktop.remote-desktop.vnc enable true
+
+  pipewire &
+  _p1=$!
+
+  wireplumber &
+  _p2=$!
+
+  trap "kill $_p1 $_p2; wait" EXIT
+
+  meson test -C build --print-errorlogs -t 3
+)
+
+check() {
+  dbus-run-session bash -c "$(declare -f _check); _check"
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}