[arch-commits] Commit in totem/repos (2 files)
Jan Steffens
heftig at gemini.archlinux.org
Sat Apr 2 23:31:41 UTC 2022
Date: Saturday, April 2, 2022 @ 23:31:40
Author: heftig
Revision: 441366
archrelease: copy trunk to gnome-unstable-x86_64
Added:
totem/repos/gnome-unstable-x86_64/
totem/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 441365, totem/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: totem/repos/gnome-unstable-x86_64/PKGBUILD (from rev 441365, totem/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2022-04-02 23:31:40 UTC (rev 441366)
@@ -0,0 +1,50 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=totem
+pkgver=42.0
+pkgrel=1
+pkgdesc="Movie player for the GNOME desktop based on GStreamer"
+url="https://wiki.gnome.org/Apps/Videos"
+arch=(x86_64)
+license=(GPL2 custom)
+depends=(totem-plparser iso-codes libpeas grilo gsettings-desktop-schemas
+ python-gobject gnome-desktop gst-plugins-base gst-plugins-good
+ gst-plugins-bad gst-plugin-gtk libhandy)
+makedepends=(libnautilus-extension itstool docbook-xsl python-pylint
+ gobject-introspection git appstream-glib gtk-doc meson intltool)
+optdepends=('gst-plugins-ugly: Extra media codecs'
+ 'gst-libav: Extra media codecs'
+ 'grilo-plugins: Media discovery')
+conflicts=(totem-plugin)
+replaces=(totem-plugin)
+groups=(gnome)
+options=(debug)
+_commit=d578333de76dc51f7a58bd84edee8ee93f5050e3 # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/totem.git#commit=$_commit"
+ "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd totem
+ git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+ cd totem
+
+ git submodule init
+ git submodule set-url subprojects/libgd "$srcdir/libgd"
+ git submodule update
+}
+
+build() {
+ arch-meson totem build -D enable-gtk-doc=true
+ meson compile -C build
+}
+
+package() {
+ meson install -C build --destdir "$pkgdir"
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 totem/COPYING
+}
More information about the arch-commits
mailing list