[arch-commits] Commit in python-rpy2/trunk (PKGBUILD)

[Antonio Rojas]

    Date: Sunday, April 3, 2022 @ 20:39:33
  Author: arojas
Revision: 1181113

Update to 3.5.0, run tests

Modified:
  python-rpy2/trunk/PKGBUILD

----------+
 PKGBUILD |   24 ++++++++++++++++++------
 1 file changed, 18 insertions(+), 6 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-03 20:27:35 UTC (rev 1181112)
+++ PKGBUILD	2022-04-03 20:39:33 UTC (rev 1181113)
@@ -4,20 +4,32 @@
 # Contributor: David Pretty <david.pretty at gmail.com> 
 
 pkgname=python-rpy2
-pkgver=3.4.5
-pkgrel=3
+pkgver=3.5.0
+pkgrel=1
 pkgdesc='A very simple, yet robust, Python interface to the R Programming Language'
 arch=(x86_64)
 url='https://rpy2.github.io/'
 license=(MPL GPL LGPL)
-depends=(python-cffi python-numpy python-tzlocal r)
-makedepends=(python-setuptools)
+depends=(python-cffi python-numpy python-tzlocal python-jinja r)
+makedepends=(python-build python-installer python-setuptools python-wheel)
+checkdepends=(python-pytest)
 optdepends=('python-pandas: conversion between rpy and pandas')
 source=(https://pypi.io/packages/source/r/rpy2/rpy2-$pkgver.tar.gz)
-sha256sums=('5d31a5ea43f5a59f6dec30faca87edb01fc9b8affa0beae96a99be923bd7dab3')
+sha256sums=('4d8a20253320ae3e402ec20d56640772bdc27731bd14f7d0475a95d86e7cd1c7')
 
+build() {
+  cd rpy2-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd rpy2-$pkgver
+  PYTHONPATH="$PWD"/`echo build/lib.*` \
+  pytest -v -k 'not test_rendertofile and not test_rendertobytes_plot' # Skip test that segfaults in build server
+}
+
 package() {
   cd rpy2-$pkgver
 
-  python setup.py install --prefix=/usr --install-data=/usr/share --root="$pkgdir" --optimize=1
+  python -m installer --destdir="$pkgdir" dist/*.whl
 }