[arch-commits] Commit in orca/repos (testing-any testing-any/PKGBUILD)

[Jan Steffens]

    Date: Monday, April 4, 2022 @ 01:51:01
  Author: heftig
Revision: 441474

archrelease: copy trunk to testing-any

Added:
  orca/repos/testing-any/
  orca/repos/testing-any/PKGBUILD
    (from rev 441473, orca/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: orca/repos/testing-any/PKGBUILD (from rev 441473, orca/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2022-04-04 01:51:01 UTC (rev 441474)
@@ -0,0 +1,45 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: William Rea <sillywilly at gmail.com>
+
+pkgname=orca
+pkgver=42.0
+pkgrel=1
+pkgdesc="Screen reader for individuals who are blind or visually impaired"
+url="https://wiki.gnome.org/Projects/Orca"
+arch=(any)
+license=(LGPL)
+depends=(
+  gtk3 at-spi2-atk python-atspi python-dbus python-xdg speech-dispatcher
+  liblouis brltty xorg-xmodmap gsettings-desktop-schemas
+  gst-plugins-base # playbin, audiotestsrc, basic decoders
+  gst-plugins-good # pulsesink, more decoders
+)
+makedepends=(itstool git yelp-tools)
+groups=(gnome)
+_commit=e226add72212718db5960889bb2f7ddced17981b  # tags/ORCA_42_0^0
+source=("git+https://gitlab.gnome.org/GNOME/orca.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/ORCA_//;s/_/\./g;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set sw=2 et: