[arch-commits] Commit in libsndfile/trunk (PKGBUILD)

David Runge dvzrv at gemini.archlinux.org
Mon Apr 4 08:36:44 UTC 2022


    Date: Monday, April 4, 2022 @ 08:36:43
  Author: dvzrv
Revision: 441495

upgpkg: libsndfile 1.1.0-1: Upgrade to 1.1.0.

Remove unneeded quotes and curly braces.
Simplify calls to cmake and make to adhere to cmake package guidelines.

Modified:
  libsndfile/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++----------------------
 1 file changed, 20 insertions(+), 22 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-04 05:46:20 UTC (rev 441494)
+++ PKGBUILD	2022-04-04 08:36:43 UTC (rev 441495)
@@ -1,54 +1,52 @@
 # Maintainer: David Runge <dvzrv at archlinux.org>
 
 pkgname=libsndfile
-pkgver=1.0.31
+pkgver=1.1.0
 pkgrel=1
 pkgdesc="A C library for reading and writing files containing sampled audio data"
-arch=('x86_64')
+arch=(x86_64)
 url="https://libsndfile.github.io/libsndfile/"
-license=('LGPL2.1')
-depends=('glibc' 'opus' 'speex')
-makedepends=('alsa-lib' 'cmake' 'flac' 'libogg' 'libvorbis' 'python' 'sqlite')
+license=(LGPL2.1)
+depends=(glibc opus speex)
+makedepends=(alsa-lib cmake flac libogg libvorbis python sqlite)
 optdepends=('alsa-lib: for sndfile-play')
-provides=('libsndfile.so')
-source=("https://github.com/${pkgname}/${pkgname}/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.bz2"{,.sig})
-sha512sums=('62202092e5cac6346fd3c0a977380e9bf888fc59d08c9c9707dc254a8ef6ed6356da2ab0430bb970c7b06ba5bb1dafa5d7b0fe13898834c1fe4acb16f409f0e1'
+provides=(libsndfile.so)
+source=(https://github.com/$pkgname/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.xz{,.asc})
+sha512sums=('d01696a8a88a4444e5eb91a137cf7b26b55b12c1fe3b648653f7e78674bbdf61870066216c9ff2f6a1e63bdf7b558af9a759480cf6523b607d29347b12762006'
             'SKIP')
-b2sums=('33e3c3d111427e829d8233aec52c227188834936839da9a04cf1ea5d2595d6a3127e7ce86d7686ca0336cca2017e6e2466845c27c7fc399efae34a0902316e41'
+b2sums=('ff2d27bff460c4d3c549bdf70c84c6f17a2c3e10674a44216ed83e657e603ddfbc33afe0827676fc4f5dc7745a9fb6aa866023fe589d0c00714477e3a246e5f2'
         'SKIP')
-validpgpkeys=('6A91A5CF22C24C99A35E013FCFDCF91FB242ACED'  # Erik de Castro Lopo <erikd at mega-nerd.com>
-              '9B1CFD2E92239C4B288E025F9D0D1F1CCB35FF8C'  # evpobr evpobr at gmail.com
-              '31D95CAB6D80D262244A1750A47620E801E47E95'  # David Seifert soap at gentoo.org
+validpgpkeys=(
+  '6A91A5CF22C24C99A35E013FCFDCF91FB242ACED'  # Erik de Castro Lopo <erikd at mega-nerd.com>
+  '9B1CFD2E92239C4B288E025F9D0D1F1CCB35FF8C'  # evpobr evpobr at gmail.com
+  '31D95CAB6D80D262244A1750A47620E801E47E95'  # David Seifert soap at gentoo.org
 )
 
 build() {
-  cd "$pkgname-$pkgver"
   # tests can only be built with static libs
   cmake -DCMAKE_INSTALL_PREFIX=/usr \
-        -DCMAKE_BUILD_TYPE='None' \
+        -DCMAKE_BUILD_TYPE=None \
         -Wno-dev \
         -B build-test \
-        -S .
+        -S $pkgname-$pkgver
   make VERBOSE=1 -C build-test
 
   cmake -DCMAKE_INSTALL_PREFIX=/usr \
-        -DCMAKE_BUILD_TYPE='None' \
+        -DCMAKE_BUILD_TYPE=None \
         -DBUILD_SHARED_LIBS=ON \
         -Wno-dev \
         -B build \
-        -S .
+        -S $pkgname-$pkgver
   make VERBOSE=1 -C build
 }
 
 check() {
-  cd "$pkgname-$pkgver"
   make test -C build-test
 }
 
 package() {
-  depends+=('libFLAC.so' 'libogg.so' 'libvorbis.so' 'libvorbisenc.so')
-  cd "$pkgname-$pkgver"
+  depends+=(libFLAC.so libogg.so libvorbis.so libvorbisenc.so)
+
   make DESTDIR="$pkgdir" install -C build
-  install -vDm 644 {AUTHORS,ChangeLog,NEWS,README} \
-    -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -vDm 644 $pkgname-$pkgver/{AUTHORS,ChangeLog,README} -t "$pkgdir/usr/share/doc/$pkgname"
 }



More information about the arch-commits mailing list