[arch-commits] Commit in gedit-plugins/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Monday, April 4, 2022 @ 18:51:57
  Author: heftig
Revision: 441538

archrelease: copy trunk to testing-x86_64

Added:
  gedit-plugins/repos/testing-x86_64/
  gedit-plugins/repos/testing-x86_64/PKGBUILD
    (from rev 441537, gedit-plugins/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: gedit-plugins/repos/testing-x86_64/PKGBUILD (from rev 441537, gedit-plugins/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-04-04 18:51:57 UTC (rev 441538)
@@ -0,0 +1,50 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: Hugo Doria <hugo at archlinux.org>
+# Contributor: Sergej Chodarev <sergejx at centrum.sk>
+# Contributor: zhuqin <zhuqin83 at gmail.com>
+
+pkgname=gedit-plugins
+pkgver=42.0
+pkgrel=1
+pkgdesc="Collection of plugins for the gedit Text Editor"
+url="https://wiki.gnome.org/Apps/Gedit/ShippedPlugins"
+arch=(x86_64)
+license=(GPL)
+depends=(gedit python-dbus python-cairo)
+makedepends=(vte3 libgit2-glib gucharmap gobject-introspection vala yelp-tools
+             appstream-glib git meson)
+optdepends=('gucharmap: for charmap plugin'
+            'vte3: for embedded terminal'
+            'libgit2-glib: for git plugin')
+options=(debug)
+_commit=a8abe1aa5e10fbd5f7114b2e7a31e6edcafaa251  # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gedit-plugins.git#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+  python -m compileall -d /usr "$pkgdir/usr"
+  python -O -m compileall -d /usr "$pkgdir/usr"
+}
+
+# vim:set sw=2 et: