[arch-commits] Commit in python-inflect/repos/community-any (PKGBUILD PKGBUILD)

[David Runge]

    Date: Wednesday, April 6, 2022 @ 08:39:17
  Author: dvzrv
Revision: 1181580

archrelease: copy trunk to community-any

Added:
  python-inflect/repos/community-any/PKGBUILD
    (from rev 1181579, python-inflect/trunk/PKGBUILD)
Deleted:
  python-inflect/repos/community-any/PKGBUILD

----------+
 PKGBUILD |   72 ++++++++++++++++++++++++++++++++-----------------------------
 1 file changed, 38 insertions(+), 34 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-06 08:39:10 UTC (rev 1181579)
+++ PKGBUILD	2022-04-06 08:39:17 UTC (rev 1181580)
@@ -1,34 +0,0 @@
-# Maintainer: David Runge <dvzrv at archlinux.org>
-
-_name=inflect
-pkgname=python-inflect
-pkgver=5.4.0
-pkgrel=1
-pkgdesc="Correctly generate plurals, singular nouns, ordinals, indefinite articles"
-arch=(any)
-url="https://github.com/jazzband/inflect"
-license=(MIT)
-depends=(python)
-makedepends=(python-setuptools-scm python-toml)
-checkdepends=(python-pytest)
-source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
-sha512sums=('48b7d38faf41b3f682226b66ea5493b7d4ff58a8db52c9b90092fc329aee761b090791deeda24234b9f9fa47d8db9b499e1f4304367ef3637c441959e8b8d005')
-b2sums=('60898e019c04b9d86a1591c341f48e7e3093eaa4f93bb4f902f4d405f1151d705f902b792028ca97a85ed47ffe509bab758b3ec74878ec82f5dac3c953197ca0')
-
-build() {
-  cd "${_name}-$pkgver"
-  python setup.py build
-}
-
-check() {
-  cd "${_name}-$pkgver"
-  export PYTHONPATH="build:${PYTHONPATH}"
-  pytest -v -c /dev/null
-}
-
-package() {
-  cd "${_name}-$pkgver"
-  python setup.py install --optimize=1 --root="${pkgdir}"
-  install -vDm 644 {CHANGES,README}.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
-  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
-}

Copied: python-inflect/repos/community-any/PKGBUILD (from rev 1181579, python-inflect/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-04-06 08:39:17 UTC (rev 1181580)
@@ -0,0 +1,38 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=inflect
+pkgname=python-inflect
+pkgver=5.5.2
+pkgrel=1
+pkgdesc="Correctly generate plurals, singular nouns, ordinals, indefinite articles"
+arch=(any)
+url="https://github.com/jazzband/inflect"
+license=(MIT)
+depends=(python)
+makedepends=(python-build python-installer python-setuptools-scm python-toml python-wheel)
+checkdepends=(python-pytest)
+source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
+sha512sums=('836ae6ec8dd450d6ffca5e69ac1b4889c631fa0caf9326716b571a56aec9feace33894a35cd87a56dadd7ecdd2586cde12345a6b06368ef485ef9ce2b117d137')
+b2sums=('60bfeedc6a106b5b2715aebe158670fe18c097f7b28a353b6225d71366723113ff247fc9d23d5e740385811dfa335f1c67fa1497712854e3140ff3b0a150459a')
+
+build() {
+  cd $_name-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  local _site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+
+  cd $_name-$pkgver
+  # install to temporary location, as importlib is used
+  python -m installer --destdir=test_dir dist/*.whl
+  export PYTHONPATH="test_dir/$_site_packages:$PYTHONPATH"
+  pytest -vv -c /dev/null
+}
+
+package() {
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 {CHANGES,README}.rst -t "$pkgdir/usr/share/doc/$pkgname/"
+  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+}