[arch-commits] Commit in ghex/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Wednesday, April 6, 2022 @ 23:01:23
  Author: heftig
Revision: 441693

archrelease: copy trunk to extra-x86_64

Added:
  ghex/repos/extra-x86_64/PKGBUILD
    (from rev 441691, ghex/trunk/PKGBUILD)
Deleted:
  ghex/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   92 +++++++++++++++++++++++++++++++++++--------------------------
 1 file changed, 53 insertions(+), 39 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-06 23:01:22 UTC (rev 441692)
+++ PKGBUILD	2022-04-06 23:01:23 UTC (rev 441693)
@@ -1,39 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Jan de Groot <jgc at archlinux.org>
-# Contributor: Tobias Kieslich <tobias at justdreams.de>
-
-pkgname=ghex
-pkgver=3.41.1
-pkgrel=1
-pkgdesc="A simple binary editor for the Gnome desktop"
-url="https://wiki.gnome.org/Apps/Ghex"
-arch=(x86_64)
-license=(GPL)
-depends=(gtk3)
-makedepends=(git meson yelp-tools)
-groups=(gnome-extra)
-_commit=2bd5cb649e40de5e3b197ce7666ee9bd14ae2c24  # tags/3.41.1^0
-source=("git+https://gitlab.gnome.org/GNOME/ghex.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-}
-
-build() {
-  arch-meson $pkgname build
-  meson compile -C build
-}
-
-check() {
-  meson test -C build --print-errorlogs
-}
-
-package() {
-  meson install -C build --destdir "$pkgdir"
-}

Copied: ghex/repos/extra-x86_64/PKGBUILD (from rev 441691, ghex/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-04-06 23:01:23 UTC (rev 441693)
@@ -0,0 +1,53 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at justdreams.de>
+
+pkgbase=ghex
+pkgname=(ghex ghex-docs)
+pkgver=42.0
+pkgrel=1
+pkgdesc="A simple binary editor for the Gnome desktop"
+url="https://wiki.gnome.org/Apps/Ghex"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk4)
+makedepends=(git meson yelp-tools gobject-introspection gi-docgen)
+options=(debug)
+_commit=c28eaa930ee7f88e56b003e81037dd9828ccc5b1  # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/ghex.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd ghex
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd ghex
+}
+
+build() {
+  arch-meson ghex build -D gtk_doc=true
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package_ghex() {
+  provides=(libgtkhex-4.so)
+  groups=(gnome-extra)
+
+  meson install -C build --destdir "$pkgdir"
+
+  mkdir -p doc/usr/share
+  mv {"$pkgdir",doc}/usr/share/doc
+}
+
+package_ghex-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+
+  mv doc/* "$pkgdir"
+}