[arch-commits] Commit in mutter/repos/extra-x86_64 (PKGBUILD PKGBUILD)

Jan Steffens heftig at gemini.archlinux.org
Thu Apr 7 08:53:51 UTC 2022


    Date: Thursday, April 7, 2022 @ 08:53:51
  Author: heftig
Revision: 441702

archrelease: copy trunk to extra-x86_64

Added:
  mutter/repos/extra-x86_64/PKGBUILD
    (from rev 441701, mutter/trunk/PKGBUILD)
Deleted:
  mutter/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  192 +++++++++++++++++++++++++++++++------------------------------
 1 file changed, 99 insertions(+), 93 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-07 08:53:34 UTC (rev 441701)
+++ PKGBUILD	2022-04-07 08:53:51 UTC (rev 441702)
@@ -1,93 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Ionut Biru <ibiru at archlinux.org>
-# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
-
-pkgbase=mutter
-pkgname=(mutter mutter-docs)
-pkgver=42.0
-pkgrel=1
-pkgdesc="A window manager for GNOME"
-url="https://gitlab.gnome.org/GNOME/mutter"
-arch=(x86_64)
-license=(GPL)
-depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
-         libcanberra startup-notification zenity libsm gnome-desktop 
-         libxkbcommon-x11 gnome-settings-daemon libgudev libinput pipewire
-         xorg-xwayland graphene libxkbfile libsysprof-capture)
-makedepends=(gobject-introspection git egl-wayland meson xorg-server
-             wayland-protocols sysprof gi-docgen)
-checkdepends=(xorg-server-xvfb pipewire-media-session python-dbusmock)
-options=(debug)
-_commit=9249aba72a5c4454894c08735a4963ca1665e34d  # tags/42.0^0
-source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd mutter
-  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
-}
-
-prepare() {
-  cd mutter
-}
-
-build() {
-  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
-  LDFLAGS+=" -Wl,-Bsymbolic-functions"
-
-  arch-meson mutter build \
-    -D egl_device=true \
-    -D wayland_eglstream=true \
-    -D docs=true \
-    -D installed_tests=false
-  meson compile -C build
-}
-
-_check() (
-  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
-  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
-  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
-
-  pipewire &
-  _p1=$!
-
-  pipewire-media-session &
-  _p2=$!
-
-  trap "kill $_p1 $_p2; wait" EXIT
-
-  meson test -C build --print-errorlogs -t 3
-)
-
-check() {
-  dbus-run-session xvfb-run -s '-nolisten local +iglx -noreset' \
-    bash -c "$(declare -f _check); _check"
-}
-
-_pick() {
-  local p="$1" f d; shift
-  for f; do
-    d="$srcdir/$p/${f#$pkgdir/}"
-    mkdir -p "$(dirname "$d")"
-    mv "$f" "$d"
-    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
-  done
-}
-
-package_mutter() {
-  provides=(libmutter-10.so)
-  groups=(gnome)
-
-  meson install -C build --destdir "$pkgdir"
-
-  _pick docs "$pkgdir"/usr/share/mutter-*/doc
-}
-
-package_mutter-docs() {
-  pkgdesc+=" (documentation)"
-  depends=()
-
-  mv docs/* "$pkgdir"
-}
-
-# vim:set sw=2 et:

Copied: mutter/repos/extra-x86_64/PKGBUILD (from rev 441701, mutter/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-04-07 08:53:51 UTC (rev 441702)
@@ -0,0 +1,99 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgbase=mutter
+pkgname=(mutter mutter-docs)
+pkgver=42.0
+pkgrel=2
+pkgdesc="A window manager for GNOME"
+url="https://gitlab.gnome.org/GNOME/mutter"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
+         libcanberra startup-notification zenity libsm gnome-desktop 
+         libxkbcommon-x11 gnome-settings-daemon libgudev libinput pipewire
+         xorg-xwayland graphene libxkbfile libsysprof-capture)
+makedepends=(gobject-introspection git egl-wayland meson xorg-server
+             wayland-protocols sysprof gi-docgen)
+checkdepends=(xorg-server-xvfb wireplumber python-dbusmock)
+options=(debug)
+_commit=9249aba72a5c4454894c08735a4963ca1665e34d  # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd mutter
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd mutter
+
+  # Fix Dash-to-dock not autohiding
+  git cherry-pick -n 2aad56b949b8 0280b0aaa563
+
+  # https://bugs.archlinux.org/task/74360
+  git cherry-pick -n f9857cb8bd7af20e819283917ae165fa40c19f07
+}
+
+build() {
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+
+  arch-meson mutter build \
+    -D egl_device=true \
+    -D wayland_eglstream=true \
+    -D docs=true \
+    -D installed_tests=false
+  meson compile -C build
+}
+
+_check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  pipewire &
+  _p1=$!
+
+  wireplumber &
+  _p2=$!
+
+  trap "kill $_p1 $_p2; wait" EXIT
+
+  meson test -C build --print-errorlogs -t 3
+)
+
+check() {
+  dbus-run-session xvfb-run -s '-nolisten local +iglx -noreset' \
+    bash -c "$(declare -f _check); _check"
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_mutter() {
+  provides=(libmutter-10.so)
+  groups=(gnome)
+
+  meson install -C build --destdir "$pkgdir"
+
+  _pick docs "$pkgdir"/usr/share/mutter-*/doc
+}
+
+package_mutter-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+
+  mv docs/* "$pkgdir"
+}
+
+# vim:set sw=2 et:



More information about the arch-commits mailing list