[arch-commits] Commit in python-pylint/repos/community-any (PKGBUILD PKGBUILD)

[Caleb Maclennan]

    Date: Thursday, April 7, 2022 @ 08:58:44
  Author: alerque
Revision: 1182774

archrelease: copy trunk to community-any

Added:
  python-pylint/repos/community-any/PKGBUILD
    (from rev 1182773, python-pylint/trunk/PKGBUILD)
Deleted:
  python-pylint/repos/community-any/PKGBUILD

----------+
 PKGBUILD |  125 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 63 insertions(+), 62 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-04-07 08:58:37 UTC (rev 1182773)
+++ PKGBUILD	2022-04-07 08:58:44 UTC (rev 1182774)
@@ -1,62 +0,0 @@
-# Maintainer: Caleb Maclennan <caleb at alerque.com>
-# Contributor: Angel Velasquez <angvp at archlinux.org>
-# Contributor: Felix Yan <felixonmars at archlinux.org>
-# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
-# Contributor: Alexander Fehr <pizzapunk gmail com>
-
-_pyname=pylint
-pkgname=python-$_pyname
-pkgver=2.13.4
-pkgrel=1
-pkgdesc='Analyzes Python code looking for bugs and signs of poor quality'
-arch=(any)
-url=https://pylint.org
-license=(GPL)
-_pydeps=(astroid
-         dill
-         isort
-         mccabe
-         platformdirs
-         toml
-         typing_extensions) # for python<3.10
-depends=(python
-         "${_pydeps[@]/#/python-}")
-makedepends=(python-{build,installer}
-             python-setuptools
-             python-sphinx
-             python-wheel)
-checkdepends=(mpdecimal
-              python-gitpython
-              python-pytest{,-timeout})
-optdepends=('graphviz: Enable output formats other than dot or vcg'
-            'tk: Pylint GUI')
-_archive="$_pyname-$pkgver"
-source=("https://github.com/PyCQA/pylint/archive/v$pkgver/$_archive.tar.gz")
-sha256sums=('34a5550bfe94f4ba04eee95367572224bc16dbd2456b3ece5fb92e15399f6cd8')
-
-prepare() {
-	cd "$_archive"
-	# Remove overly restrictive dependency pinning that ends up in runtime checks
-	sed -i -e '/>=/{s/>.*//;p}' -e '/python_requires/d' setup.cfg
-	# Give ourselves a way to granularly disable test dependent on installed path
-	sed -i -e '/^markers =/a\    pathdependent: Does not play nice' setup.cfg
-	sed -i -e '/test_do_not_import_files_from_local_directory_with_pythonpath/i\    @pytest.mark.pathdependent' tests/test_self.py
-}
-
-build() {
-	cd "$_archive"
-	python -m build -wn
-	make PYTHONPATH="$PWD/build/lib" -C doc man
-}
-
-check() {
-	cd "$_archive"
-	PYTHONPATH="$PWD:$PWD/build/lib" pytest -m 'not pathdependent' \
-		--deselect tests/benchmark/test_baseline_benchmarks.py
-}
-
-package() {
-	cd "$_archive"
-	python -m installer -d "$pkgdir" dist/*.whl
-	install -Dm0644 -t "$pkgdir/usr/share/man/man1/" doc/_build/man/*
-}

Copied: python-pylint/repos/community-any/PKGBUILD (from rev 1182773, python-pylint/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-04-07 08:58:44 UTC (rev 1182774)
@@ -0,0 +1,63 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+
+_pyname=pylint
+pkgname=python-$_pyname
+pkgver=2.13.5
+pkgrel=1
+pkgdesc='Analyzes Python code looking for bugs and signs of poor quality'
+arch=(any)
+url=https://pylint.org
+license=(GPL)
+_pydeps=(astroid
+         dill
+         isort
+         mccabe
+         platformdirs
+         toml
+         typing_extensions) # for python<3.10
+depends=(python
+         "${_pydeps[@]/#/python-}")
+makedepends=(python-{build,installer}
+             python-setuptools
+             python-sphinx
+             python-wheel)
+checkdepends=(mpdecimal
+              python-gitpython
+              python-pytest{,-timeout})
+optdepends=('graphviz: Enable output formats other than dot or vcg'
+            'tk: Pylint GUI')
+_archive="$_pyname-$pkgver"
+source=("https://github.com/PyCQA/pylint/archive/v$pkgver/$_archive.tar.gz")
+sha256sums=('5450fd8014baf1663fb4860b7e1dc4f4c4eb9649598a210d68e97be0973c783f')
+
+prepare() {
+	cd "$_archive"
+	# Remove overly restrictive dependency pinning that ends up in runtime checks
+	sed -i -e '/>=/{s/>.*//;p}' -e '/python_requires/d' setup.cfg
+	# Give ourselves a way to granularly disable test dependent on installed path
+	sed -i -e '/^markers =/a\    pathdependent: Does not play nice' setup.cfg
+	sed -i -e '/test_do_not_import_files_from_local_directory_with_pythonpath/i\    @pytest.mark.pathdependent' tests/test_self.py
+}
+
+build() {
+	cd "$_archive"
+	python -m build -wn
+	make PYTHONPATH="$PWD/build/lib" -C doc man
+}
+
+check() {
+	cd "$_archive"
+	PYTHONPATH="$PWD:$PWD/build/lib" pytest \
+		-m 'not pathdependent' \
+		--deselect tests/benchmark/test_baseline_benchmarks.py
+}
+
+package() {
+	cd "$_archive"
+	python -m installer -d "$pkgdir" dist/*.whl
+	install -Dm0644 -t "$pkgdir/usr/share/man/man1/" doc/_build/man/*
+}