[arch-commits] Commit in libva/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jelle van der Waa]

    Date: Thursday, April 7, 2022 @ 20:08:56
  Author: jelle
Revision: 441731

archrelease: copy trunk to testing-x86_64

Added:
  libva/repos/testing-x86_64/
  libva/repos/testing-x86_64/PKGBUILD
    (from rev 441730, libva/trunk/PKGBUILD)

----------+
 PKGBUILD |   64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

Copied: libva/repos/testing-x86_64/PKGBUILD (from rev 441730, libva/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-04-07 20:08:56 UTC (rev 441731)
@@ -0,0 +1,64 @@
+# Maintainer: Maxime Gauduin <alucryd at archlonux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=libva
+pkgver=2.14.0
+pkgrel=1
+pkgdesc='Video Acceleration (VA) API for Linux'
+arch=(x86_64)
+url=https://01.org/linuxmedia/vaapi
+license=(MIT)
+depends=(
+  libdrm
+  libgl
+  libx11
+  libxext
+  libxfixes
+  wayland
+)
+makedepends=(
+  git
+  libglvnd
+  mesa
+  meson
+)
+optdepends=(
+  'intel-media-driver: backend for Intel GPUs (>= Broadwell)'
+  'libva-vdpau-driver: backend for Nvidia and AMD GPUs'
+  'libva-intel-driver: backend for Intel GPUs (<= Haswell)'
+)
+provides=(
+  libva-drm.so
+  libva-glx.so
+  libva-wayland.so
+  libva-x11.so
+  libva.so
+)
+backup=(etc/libva.conf)
+_tag=eec9f7132d4677575f929fc1dd3babc349cc56da
+source=(git+https://github.com/intel/libva.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd libva
+
+  git describe --tags
+}
+
+build() {
+  CFLAGS+=" -DENABLE_VA_MESSAGING"  # Option missing
+  arch-meson libva build
+  ninja -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  install -Dm 644 libva/COPYING -t "${pkgdir}"/usr/share/licenses/libva
+
+  install -Dm 644 /dev/stdin "${pkgdir}"/etc/libva.conf <<END
+LIBVA_MESSAGING_LEVEL=1
+END
+}
+
+# vim: ts=2 sw=2 et: