[arch-commits] Commit in haskell-persistent/repos (2 files)

[Felix Yan]

    Date: Thursday, April 7, 2022 @ 22:33:42
  Author: felixonmars
Revision: 1182873

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent/repos/community-staging-x86_64/
  haskell-persistent/repos/community-staging-x86_64/PKGBUILD
    (from rev 1182872, haskell-persistent/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-persistent/repos/community-staging-x86_64/PKGBUILD (from rev 1182872, haskell-persistent/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-04-07 22:33:42 UTC (rev 1182873)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=persistent
+pkgname=haskell-persistent
+pkgver=2.13.3.0
+pkgrel=1
+pkgdesc="Type-safe, multi-backend data serialization"
+url="http://www.yesodweb.com/book/persistent"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-base64-bytestring'
+         'haskell-blaze-html' 'haskell-conduit' 'haskell-fast-logger' 'haskell-http-api-data'
+         'haskell-lift-type' 'haskell-monad-logger' 'haskell-path-pieces' 'haskell-resource-pool'
+         'haskell-resourcet' 'haskell-scientific' 'haskell-silently' 'haskell-th-lift-instances'
+         'haskell-unordered-containers' 'haskell-unliftio' 'haskell-unliftio-core' 'haskell-vault'
+         'haskell-vector')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck' 'haskell-quickcheck-instances'
+             'haskell-shakespeare')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('6d85ce88e31ca2d81b1442f53d67b642c2ce63f678c00e11db1dd682ae1ee57ee3e85dbd50b4371bc8c23891a68496bba6b4a707c6f5b38e541da421540c78be')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-nooverlap
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}