[arch-commits] Commit in (4 files)

[Antonio Rojas]

    Date: Friday, April 8, 2022 @ 17:32:33
  Author: arojas
Revision: 1183006

extra2community: Moving ttf-dejavu from extra to community

Added:
  ttf-dejavu/
  ttf-dejavu/repos/
  ttf-dejavu/trunk/
  ttf-dejavu/trunk/PKGBUILD

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Added: ttf-dejavu/trunk/PKGBUILD
===================================================================
--- ttf-dejavu/trunk/PKGBUILD	                        (rev 0)
+++ ttf-dejavu/trunk/PKGBUILD	2022-04-08 17:32:33 UTC (rev 1183006)
@@ -0,0 +1,37 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Michal Krenek <mikos at sg1.cz>
+
+pkgname=ttf-dejavu
+pkgver=2.37+18+g9b5d1b2f
+pkgrel=3
+pkgdesc="Font family based on the Bitstream Vera Fonts with a wider range of characters"
+arch=('any')
+url="https://dejavu-fonts.github.io/"
+license=('custom')
+makedepends=('git' 'fontforge' 'perl-font-ttf')
+provides=('ttf-font')
+_commit=9b5d1b2ffeec20c7b46aa89c0223d783c02762cf  # master
+source=("git+https://github.com/dejavu-fonts/dejavu-fonts.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd dejavu-fonts
+  git describe --tags | sed 's/^version_//;s/_/./;s/-/+/g'
+}
+
+build() {
+  cd dejavu-fonts
+  make full-ttf
+}
+
+package() {
+  cd dejavu-fonts
+  install -Dt "$pkgdir/usr/share/fonts/TTF" -m644 build/*.ttf
+  install -Dt "$pkgdir/usr/share/fontconfig/conf.avail" -m644 fontconfig/*.conf
+
+  mkdir "$pkgdir/usr/share/fontconfig/conf.default"
+  ln -srt "$pkgdir/usr/share/fontconfig/conf.default" \
+    "$pkgdir"/usr/share/fontconfig/conf.avail/*
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE
+}