[arch-commits] Commit in mingw-w64-binutils/repos (2 files)

[Felix Yan]

    Date: Saturday, April 9, 2022 @ 00:02:12
  Author: felixonmars
Revision: 1183092

archrelease: copy trunk to community-testing-x86_64

Added:
  mingw-w64-binutils/repos/community-testing-x86_64/
  mingw-w64-binutils/repos/community-testing-x86_64/PKGBUILD
    (from rev 1183091, mingw-w64-binutils/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: mingw-w64-binutils/repos/community-testing-x86_64/PKGBUILD (from rev 1183091, mingw-w64-binutils/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-04-09 00:02:12 UTC (rev 1183092)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=mingw-w64-binutils
+pkgver=2.38
+pkgrel=1
+pkgdesc="Cross binutils for the MinGW-w64 cross-compiler"
+arch=('x86_64')
+url="http://www.gnu.org/software/binutils"
+license=('GPL')
+groups=('mingw-w64-toolchain' 'mingw-w64')
+depends=('zlib')
+options=('!libtool' '!emptydirs')
+validpgpkeys=('3A24BC1E8FB409FA9F14371813FCEF89DD9E3C4F')  # Nick Clifton (Chief Binutils Maintainer) <nickc at redhat.com>
+source=("https://ftp.gnu.org/gnu/binutils/binutils-${pkgver}.tar.gz"{,.sig})
+sha512sums=('5160ff5c2a0ad41b880384216e21ada5328b51378e760c04269eb3b3626400d12abeeea72c14e18b52b969a0be94c8e5285c0b568bd5c82b7e69f68e0dfdc743'
+            'SKIP')
+
+_targets="i686-w64-mingw32 x86_64-w64-mingw32"
+
+prepare() {
+  cd "$srcdir"/binutils-${pkgver}
+  #do not install libiberty
+  sed -i 's/install_to_$(INSTALL_DEST) //' libiberty/Makefile.in
+}
+
+build() {
+  for _target in $_targets; do
+    echo "Building ${_target} cross binutils"
+    mkdir -p "$srcdir"/binutils-${_target} && cd "${srcdir}/binutils-${_target}"
+    "$srcdir"/binutils-${pkgver}/configure --prefix=/usr \
+        --target=${_target} \
+        --infodir=/usr/share/info/${_target} \
+        --enable-lto --enable-plugins \
+        --enable-deterministic-archives --enable-shared \
+        --disable-multilib --disable-nls \
+        --disable-werror
+     make -O
+  done
+}
+
+package() {
+  for _target in ${_targets}; do
+    echo "Installing ${_target} cross binutils"
+    cd "$srcdir"/binutils-${_target}
+    make DESTDIR="$pkgdir" install
+
+    rm "$pkgdir"/usr/lib/bfd-plugins/libdep.so
+  done
+}